+/EE306

intro to computing

git clone https://git.julia.blue/+/EE306

P1n3appl3Add projects 1 and 27702458

master
2.0 KiB70 linesraw
1; Computes f(R0), storing the result in R4
2        .ORIG x5000
3        ST R1, saver1
4        ST R2, saver2
5        ST R3, saver3
6        ST R5, saver5
7        ST R6, saver6
8        ST R7, retaddr
9        LD R6, poly
10        LDR R5, R6, #0      ; R5 = Degree
11        ADD R6, R6, #1
12        LDR R1, R6, #0      ; R1(output) = first term
13loop2   ADD R5, R5, #-1     ; Degree -= 1
14        BRn done            ; If degree <= 0: end loop
15        JSR mult            ; Output *= X
16        AND R1, R2, R2
17        ADD R6, R6, #1
18        LDR R2, R6, #0
19        ADD R1, R1, R2      ; Add next term to output
20        BR loop2
21done    AND R4, R1, R1
22        LD R1, saver1
23        LD R2, saver2
24        LD R3, saver3
25        LD R5, saver5
26        LD R6, saver6
27        LD R7, retaddr
28        RET
29poly    .FILL x4003
30saver1  .BLKW #1
31saver2  .BLKW #1
32saver3  .BLKW #1
33saver5  .BLKW #1
34saver6  .BLKW #1
35retaddr .BLKW #1
36
37; Multiplies R0 and R1 (in constant rather than linear time), placing the
38; result in R2 (clobbers R1-R4)
39mult    AND R4, R4, #0      ; Set negative flag to false
40        ST R7, saver7
41        ST R0, saver0
42        AND R0, R0, R0
43        BRzp posA           ; If R0 is negative: set it to it's absolute value
44        NOT R0, R0          ; and flip the negative flag
45        ADD R0, R0, #1
46        NOT R4, R4
47posA    AND R1, R1, R1
48        BRzp posB           ; Do the same for R1
49        NOT R1, R1
50        ADD R1, R1, #1
51        NOT R4, R4
52posB    AND R3, R3, #0
53        ADD R3, R3 #1       ; Set the mask to 1
54        AND R2, R2, #0      ; Clear the output
55loop    AND R7, R0, R3
56        BRz skip
57        ADD R2, R2, R1      ; If R0[mask] == 1: add R1 to output
58skip    ADD R1, R1, R1      ; Bitshift the mask and R1 left by one
59        ADD R3, R3, R3
60        BRnp loop           ; Repeat for each bit
61        AND R4, R4, R4
62        BRz pos             ; If the flag is enabled, negate the output
63        NOT R2, R2
64        ADD R2, R2, #1
65pos     LD R0, saver0
66        LD R7, saver7
67        RET
68saver0  .BLKW #1
69saver7  .BLKW #1
70        .END