+/EE306

intro to computing

git clone https://git.julia.blue/+/EE306

P1n3appl3Complete problem set 451dbf3f

master
2.3 KiB81 linesraw
1        .ORIG x3000
2        AND R6, R6, #0      ; R6 (slope) = 0 (positive)
3        LD R5, args
4        LDR R1, R5, #1      ; R1 = left
5        LDR R2, R5, #2      ; R2 = right
6        JSR mid
7        LD R3, func
8        JSRR R3
9        AND R5, R4, R4      ; R5 = f(mid)
10        ADD R0, R0, #1
11        JSRR R3
12        NOT R7, R4
13        ADD R7, R7, #-1     ; R7 = -f(mid+1)
14        ADD R7, R7, R5
15        BRnz pslope         ; If f(mid) >= f(mid+1): slope is positive
16        NOT R6, R6
17pslope  AND R4, R5, R5
18        BR post
19again   JSR mid             ; R0 = avg(left, right)
20        JSRR R3
21        AND R4, R4, R4
22post    BRz done            ; If f(mid) == 0: FINISH
23        BRn neg
24        AND R6, R6, R6
25        BRz right           ; If slope and f(mid) are positive: right = mid
26        BR left             ; Else: left = mid
27neg     AND R6, R6, R6
28        BRz left            ; If slope and f(mid) are negative: left = mid
29right   AND R2, R0, R0      ; else right = mid
30        BR again
31left    AND R1, R0, R0
32        BR again            ; Loop forever
33done    STI R0, args
34        HALT
35args    .FILL x4000
36func    .FILL x5000
37
38; Averages R1 and R2, avoiding overflow errors by computing R1+(R2-R1)>>1
39; rather than (R1+R2)>>1, placing the result in R0
40mid     ST R7, retaddr
41        ST R3, saver3
42        NOT R3, R1
43        ADD R3, R3, #1
44        ADD R3, R3, R2      ; R3 = R2-R1
45        JSR rshift          ; R3 >>= 1
46        ADD R0, R1, R3      ; R0 = R1+R3
47        LD R3, saver3
48        LD R7, retaddr
49        RET
50retaddr .BLKW #1
51saver3  .BLKW #1
52
53; Right shifts the contents of R3 by 1 (sign extended)
54rshift  ST R4, saver4
55        ST R5, saver5
56        ST R6, saver6
57        ST R7, saver7
58        AND R4, R4, #0
59        AND R5, R5, #0
60        LD R7, bit15        ; Sign extend
61        AND R7, R7, R3
62        ADD R4, R4, #1      ; Create 2 masks, off by 1 bit
63        ADD R5, R5, #2
64loop    AND R6, R3, R5      ; If R3[mask1] == 1: result += mask2
65        BRz noadd
66        ADD R7, R7, R4
67noadd   ADD R4, R4, R4      ; Shift masks left by 1
68        ADD R5, R5, R5
69        BRnp loop           ; Repeat for each bit
70        AND R3, R7, R7
71        LD R4, saver4
72        LD R5, saver5
73        LD R6, saver6
74        LD R7, saver7
75        RET
76saver4  .BLKW #1
77saver5  .BLKW #1
78saver6  .BLKW #1
79saver7  .BLKW #1
80bit15   .FILL x8000
81        .END