+/TECS

git clone https://git.julia.blue/+/TECS

Joseph RyanReplace Tetris with Conway's Game of Life0f59f13

v1.0
2.2 KiB74 linesraw
1class Game {
2    field Board board;
3    field boolean running; //0 for pause 1 for play
4    field int x, y;
5
6    constructor Game new(int s){
7        let board = Board.new(s);
8        let x = board.getWidth()/2;
9        let y = board.getHeight()/2;
10        let running = false;
11        return this;
12    }
13
14    method void run(){
15        var int key, temp;
16        var boolean pressed;
17        let key = 0;
18
19        while(~(key=81)){ //q for quit
20            let pressed = true;
21            let temp = Keyboard.keyPressed();
22            if(~(key=temp)){
23                let pressed = false;
24            }
25            let key = temp;
26            if(~pressed & ~(key=0)){
27                if(~running){
28                    if(key=83){ //s for step
29                        do board.step();
30                        do board.flip();
31                    }
32                    if((key=88) | (key=90)){ //x or z for toggle
33                        do board.set(x, y, ~board.get(x, y));
34                        do board.flip();
35                    }
36                    if((key=130) | (key=132)){ //left and right
37                        let x = Util.mod(x+board.getWidth()+key-131, board.getWidth());
38                    }
39                    if((key=131) | (key=133)){ //up and down
40                        let y = Util.mod(y+board.getHeight()+key-132, board.getHeight());
41                    }
42                }
43                if((key=32)|(key=128)){ //enter or space for start
44                    let running = ~running;
45                }
46                if(key=129){ //backspace for clear
47                    do board.clear();
48                    let running = false;
49                }
50                do drawCursor();
51            }
52            if(running){
53                do board.step();
54                do board.flip();
55                do board.draw();
56            }
57        }
58        return;
59    }
60
61    method void drawCursor(){
62        var int s;
63        do board.draw();
64        do Screen.setColor(~board.get(x,y));
65        let s = board.getSize();
66        do Screen.drawCircle(board.getX()+(x*s)+(s/2), board.getY()+(y*s)+(s/2), s/3);
67        return;
68    }
69
70    method void dispose(){
71        do board.dispose();
72        return;
73    }
74}