+/config

my dotfiles and nix configuration

git clone https://git.julia.blue/+/config

Julia RyanUpdate minecraft server8dbea4b

main
2.7 KiB82 linesraw
1{ config, lib, pkgs, ... } @ inputs: let
2  cfg = config.services.sorcery;
3  types = lib.types;
4  cache = "/var/cache/sorcery";
5  socket = "/run/sorcery/sock";
6  control_socket = "/run/sorcery/control";
7  pkg = inputs.inputs.sorcery.packages.x86_64-linux;
8  # TODO: remove when char fixes this upstream
9  sorcery-ssh = pkg.sorcery-ssh.overrideAttrs (old: {
10    nativeBuildInputs =
11      (lib.filter (p: p != pkgs.zig) (old.nativeBuildInputs or []))
12      ++ [ pkgs.zig_0_16 ];
13  });
14in {
15  options.services.sorcery = {
16    enable = lib.mkEnableOption (lib.mdDoc "git repo viewer");
17    repositories = lib.mkOption {
18      type = types.path;
19      description = "Directory where your git repos reside";
20    };
21    name = lib.mkOption {
22      type = types.str;
23      description = "Name of your instance";
24    };
25    url_base = lib.mkOption {
26      type = types.str;
27      description = "Where your git repos will be accessed from";
28    };
29    keys = lib.mkOption {
30      type = types.listOf types.str;
31      description = "ssh keys that have write access to your repositories";
32    };
33  };
34
35  config = lib.mkIf cfg.enable {
36    environment.systemPackages = [ pkg.default sorcery-ssh pkg.sorcery-ssh-tui ];
37    systemd.services.sorcery = {
38      description = "Sorcery Git forge";
39      wantedBy = [ "multi-user.target" ];
40      after = [ "network-online.target" ];
41      wants = [ "network-online.target" ];
42      path = [ pkgs.gitMinimal ];
43      serviceConfig = {
44        ExecStart = [ "${lib.getExe pkg.default}" ];
45        Type = "simple";
46        User = "git";
47        Group = "git";
48        RuntimeDirectory = "sorcery";
49        CacheDirectory = "sorcery";
50        ConfigurationDirectory = "sorcery";
51        Restart = "on-failure";
52        RestartSec = 2;
53        UMask = "0007";
54      };
55      environment = {
56        SORCERY_REPOSITORIES = "${cfg.repositories}";
57        SORCERY_INSTANCE_NAME = "${cfg.name}";
58        SORCERY_CLONE_URL_BASE = "${cfg.url_base}";
59        SORCERY_CACHE = "${cache}";
60        SORCERY_SOCKET = "${socket}";
61        SORCERY_CONTROL_SOCKET = "${control_socket}";
62      };
63    };
64    services.openssh.extraConfig = ''
65      Match User git
66        SetEnv SORCERY_CONTROL_SOCKET=${control_socket} SORCERY_INSTANCE_NAME=${cfg.name} SORCERY_SSH_TUI=${lib.getExe pkg.sorcery-ssh-tui} SORCERY_REPOSITORIES=${cfg.repositories} SORCERY_CLONE_URL_BASE=${cfg.url_base}
67        ForceCommand ${lib.getExe sorcery-ssh}
68    '';
69
70    users = {
71      groups.git.gid = config.ids.gids.git;
72      users.git = {
73        description = "git user";
74        home = cfg.repositories;
75        group = "git";
76        uid = config.ids.uids.git;
77        shell = pkgs.bashInteractive;
78        openssh.authorizedKeys.keys = cfg.keys;
79      };
80    };
81  };
82}