+/config

my dotfiles and nix configuration

git clone https://git.julia.blue/+/config

Julia RyanMore new Cortana prep945d6d7

main
2.0 KiB80 linesraw
1{ lib, stdenv, fetchFromGitHub, nodejs, pnpmConfigHook, fetchPnpmDeps,
2  pnpm, electron, copyDesktopItems, makeDesktopItem, makeWrapper }: let
3  pname = "bridge";
4  version = "3.4.5";
5
6  src = fetchFromGitHub {
7    owner = "Geomitron";
8    repo = "Bridge";
9    rev = "v${version}";
10    hash = "sha256-le2Wj2pfq+LbqpmPBE94HfboIwpwQZ8JfyHZozfXEAs=";
11  };
12
13  pnpmDeps = fetchPnpmDeps {
14    inherit pname version src;
15
16    fetcherVersion = 4;
17    hash = "sha256-lpJyjq1+Dv2422hJF5ED4aNU13WNvk9Ce6GxttxuaPo=";
18  };
19
20  desktopItem = makeDesktopItem {
21    name = pname;
22    desktopName = "Bridge";
23    comment = "A rhythm game chart searching and downloading tool";
24    exec = pname;
25    icon = pname;
26    categories = [ "Game" "Utility" ];
27  };
28in stdenv.mkDerivation {
29  inherit pname version src;
30
31  nativeBuildInputs = [
32    nodejs
33    pnpmConfigHook
34    makeWrapper
35    copyDesktopItems
36    pnpm
37  ];
38
39  inherit pnpmDeps;
40  dontCheckForBrokenSymlinks = true;
41  desktopItems = [ desktopItem ];
42
43  buildPhase = ''
44    runHook preBuild
45
46    pnpm install --frozen-lockfile --offline
47    pnpm exec ng build -c production
48    pnpm exec tsc -p src-electron/tsconfig.electron.json
49    node src-electron/rename-to-mjs.js
50    pnpm prune --prod
51    rm -rf node_modules/.bin
52
53    runHook postBuild
54  '';
55
56  installPhase = ''
57    runHook preInstall
58
59    mkdir -p $out/share/${pname}
60    cp -R dist $out/share/${pname}/
61    cp -R node_modules $out/share/${pname}/
62    cp package.json pnpm-lock.yaml $out/share/${pname}/
63
64    install -Dm644 src-angular/assets/images/system/icons/png/512x512.png \
65      $out/share/icons/hicolor/512x512/apps/${pname}.png
66
67    mkdir -p $out/bin
68    makeWrapper ${electron}/bin/electron $out/bin/${pname} \
69      --chdir "$out/share/${pname}" \
70      --add-flags "$out/share/${pname}/dist/electron/src-electron/main.js"
71
72    runHook postInstall
73  '';
74
75  meta = with lib; {
76    description = "Rhythm game chart searching and downloading tool";
77    homepage = "https://github.com/Geomitron/Bridge";
78    license = licenses.gpl3Only;
79  };
80}