collab/mame-tgm

packaging mame for playing tgm1/2

git clone https://git.julia.blue/collab/mame-tgm

Rahul Butaniwrapper: checkpointa9fe608

main
1.6 KiB79 linesraw
1{ stdenv
2, lib
3, fetchFromGitHub
4, pkg-config
5, SDL
6, gtk2
7, gnome2
8, libGL
9, libGLU
10, testers
11, runCommand
12}:
13
14stdenv.mkDerivation (finalAttrs: let
15  mainProgram = "mametgm" + (
16    lib.optionalString stdenv.hostPlatform.is64bit "64"
17  );
18in {
19  pname = "shmupmametgm";
20  version = "2.1";
21  src = fetchFromGitHub {
22    owner = "MaryHal";
23    repo = "shmupmametgm";
24    rev = "v${finalAttrs.version}";
25    hash = "sha256-Y5crVgbLkuSPp0D0FEtJWAc44cEuFwh9XJE0F2MmRM8=";
26  };
27
28  outputs = ["out" "doc" "web"];
29
30  nativeBuildInputs = [ pkg-config ];
31  buildInputs = [ SDL gtk2 gnome2.GConf libGL libGLU ];
32
33  makeFlags = [
34    "SUBTARGET=tgm"
35    "NOWERROR=1"
36  ] ++ lib.optional stdenv.hostPlatform.is64bit "PTR64=1";
37
38  installPhase = ''
39    runHook preInstall
40
41    mkdir -p $out/bin
42    mv ${mainProgram} $out/bin
43
44    mkdir -p $web
45    mv fumen_encode* $web/
46
47    mkdir -p $doc
48    mv docs/* $doc
49
50    runHook postInstall
51  '';
52
53  passthru = let package = finalAttrs.finalPackage; in {
54    tests.smoke = testers.testVersion {
55      inherit package;
56      command = "${finalAttrs.meta.mainProgram} -h";
57      version = "v0.137"; # MAME version
58    };
59
60    defaultConfig = runCommand (package.name + "-default-config") {} ''
61      ${lib.getExe package} -createconfig
62      mv mame.ini $out
63    '';
64  };
65
66  meta = {
67    # description = "";
68    # longDescription = '''';
69    # homepage = "";
70    # changelog
71    # license
72    maintainers = with lib.maintainers; [
73      rrbutani
74      { name = "Julia Ryan"; github = "P1n3appl3"; githubId = 9326885; }
75    ];
76    inherit mainProgram;
77    # platforms
78  };
79})