collab/whiteboard

git clone https://git.julia.blue/collab/whiteboard

Jana Dönszelmannnix-stuff266b6e0

main
5.2 KiB158 linesraw
1{
2  inputs = {
3    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
4    flake-utils.url = "github:numtide/flake-utils";
5    home-manager = {
6      url = "github:nix-community/home-manager";
7      inputs.nixpkgs.follows = "nixpkgs";
8    };
9    deploy-rs.url = "github:serokell/deploy-rs";
10    rust-overlay = {
11      url = "github:oxalica/rust-overlay";
12      inputs.nixpkgs.follows = "nixpkgs";
13    };
14    # crane.url = "github:ipetkov/crane";
15
16    naersk.url = "github:nix-community/naersk";
17  };
18
19  outputs =
20    { self
21    , home-manager
22    , nixpkgs
23    , flake-utils
24    , deploy-rs
25    , rust-overlay
26    , naersk
27    , ...
28    }@inputs:
29    let
30      whiteboard-system = "aarch64-linux";
31      whiteboard-rust-target = "aarch64-unknown-linux-gnu";
32      pico-rust-target = "thumbv8m.main-none-eabihf";
33    in
34    flake-utils.lib.eachDefaultSystem
35      (
36        system:
37        let
38          pkgs = import nixpkgs {
39            inherit system;
40            overlays = [
41              rust-overlay.overlays.default
42              deploy-rs.overlay # or deploy-rs.overlays.default
43              (_: super: {
44                deploy-rs = {
45                  inherit (pkgs) deploy-rs;
46                  inherit (super.deploy-rs) lib;
47                };
48              })
49            ];
50          };
51          pkgs' = import pkgs.path {
52            localSystem.system = system;
53            crossSystem.system = "aarch64-linux";
54            overlays = [
55              rust-overlay.overlays.default
56            ];
57          };
58        in
59        rec {
60          formatter = legacyPackages.nixfmt-classic;
61          legacyPackages = pkgs;
62          devShells.default = pkgs.mkShell {
63            buildInputs = with pkgs; [
64              (writeShellScriptBin "deploy" ''
65                export NIX_BUILD_CORES=$(($(nproc) * 2))
66                ${deploy-rs.packages.${system}.deploy-rs}/bin/deploy . -s -- --cores $(nproc) -j $(($(nproc) * 2))
67              '')
68            ];
69          };
70          packages =
71            let
72              toolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
73              naersk' = pkgs.callPackage naersk {
74                cargo = toolchain;
75                rustc = toolchain;
76              };
77              rustPackage =
78                crate: target:
79                naersk'.buildPackage {
80                  root = crate;
81                  additionalCargoLock = "${toolchain.passthru.availableComponents.rust-src}/lib/rustlib/src/rust/library/Cargo.lock";
82                  cargoBuildOptions = _: [
83                    "$cargo_release"
84                    ''-j "$(nproc)"''
85                    "--message-format=$cargo_message_format"
86                    "--target ${target}"
87                  ];
88                  override = old: {
89                    inherit (old) buildPhase configurePhase;
90                    patchPhase = ''
91                      cp -r ${./shared} ../shared
92                    '';
93                    fixupPhase = "";
94                    dontStrip = 1;
95                  };
96                  release = false;
97                  CARGO_TARGET_AARCH64_UNKNOWN_LINUX_GNU_LINKER = "${pkgs'.stdenv.cc.targetPrefix}cc";
98                  HOST_CC = "${pkgs'.stdenv.cc.nativePrefix}cc";
99                  nativeBuildInputs = [ pkgs'.stdenv.cc ];
100                };
101            in
102            {
103              whiteboard-controller = rustPackage ./controller whiteboard-rust-target;
104              whiteboard-pico = rustPackage ./pico pico-rust-target;
105
106              pi-openocd = pkgs'.openocd.overrideAttrs (old: {
107                version = "raspi";
108                src = pkgs.fetchgit {
109                  url = "https://github.com/raspberrypi/openocd";
110                  sha256 = "sha256-FdR8FiZqgwZL0rJwBZoQmTWWcVcye0ue2+j+y5JlvMY=";
111                  fetchSubmodules = true;
112                  leaveDotGit = true;
113                };
114                preConfigure = ''
115                  ./bootstrap
116                '';
117                nativeBuildInputs = old.nativeBuildInputs or [ ] ++ [
118                  pkgs'.autoreconfHook269
119                  pkgs'.libtool
120                  pkgs'.which
121                  pkgs'.git
122                ];
123              });
124            };
125        }
126      )
127    // {
128
129      deploy.nodes.whiteboard = {
130        hostname = "whiteboard";
131        user = "whiteboard";
132        sshUser = "whiteboard";
133        # remoteBuild = true;
134
135        profiles.system = rec {
136          user = "whiteboard";
137          profilePath = "/nix/var/nix/profiles/per-user/${user}/home-manager";
138          path = deploy-rs.lib.${whiteboard-system}.activate.home-manager (
139            home-manager.lib.homeManagerConfiguration {
140              modules = [ ./nix/home.nix ];
141              pkgs = import nixpkgs {
142                system = whiteboard-system;
143                config.allowUnfree = true;
144                overlays = [
145                  (_: _: {
146                    # cross compile
147                    inherit (self.outputs.packages."x86_64-linux") whiteboard-controller whiteboard-pico;
148                    # compile in qemu
149                    inherit (self.outputs.packages."aarch64-linux") pi-openocd;
150                  })
151                ];
152              };
153            }
154          );
155        };
156      };
157    };
158}