fork/fish-shell

git clone https://git.julia.blue/fork/fish-shell

Johannes AltmanningerRun fish_indent on share/completions/*.fishe9bf8b9a4

master
2.2 KiB31 linesraw
1complete -c hostnamectl -f
2
3set -l __hostnamectl_version $(hostnamectl --version &| string match -rg 'systemd (\d+).*')
4if test "$__hostnamectl_version" -lt 249
5    complete -c hostnamectl -n __fish_use_subcommand -xa "status\t'Show hostname and related info'
6                                                            set-hostname\t'Set hostname'
7                                                            set-icon-name\t'Set icon name'
8                                                            set-chassis\t'Set chassis type'
9                                                            set-deployment\t'Set deployment environment'
10                                                            set-location\t'Set location'"
11else
12    complete -c hostnamectl -n __fish_use_subcommand -xa "status\t'Show hostname and related info'
13                                                            hostname\t'Get or set hostname'
14                                                            icon-name\t'Get or set icon name'
15                                                            chassis\t'Get or set chassis type'
16                                                            deployment\t'Get or set deployment environment'
17                                                            location\t'Get or set location'"
18end
19
20complete -c hostnamectl -n "__fish_seen_subcommand_from set-chassis chassis" -xa "desktop laptop convertible server tablet handset watch embedded vm container"
21complete -c hostnamectl -n "__fish_seen_subcommand_from set-deployment deployment" -xa "development integration staging production"
22
23complete -c hostnamectl -l no-ask-password -d "Don't query for authentication for privileged operations"
24complete -c hostnamectl -l static -d "Get or set static hostname"
25complete -c hostnamectl -l transient -d "Get or set transient hostname"
26complete -c hostnamectl -l pretty -d "Get or set pretty hostname"
27complete -c hostnamectl -s H -l host -x -d "Execute operation on remote host"
28complete -c hostnamectl -s M -l machine -x -d "Execute operation on local container"
29complete -c hostnamectl -s h -l help -d "Print short help"
30complete -c hostnamectl -l version -d "Print version"
31complete -c hostnamectl -l json -d "Show output as JSON" -xa "short pretty off"