fork/fish-shell

git clone https://git.julia.blue/fork/fish-shell

Johannes Altmanningercompletions/pacman: restore completions of short options attached to operation4cacb8e2c

master
14.2 KiB199 linesraw
1# Completions for pacman (https://man.archlinux.org/man/pacman.8)
2# Author: Giorgio Lando <patroclo7@gmail.com>
3# Updated by maxfl, SanskritFritz, faho, f1u77y, akiirui, marmitar
4
5set -l progname pacman
6
7# Checks if the given or any command is in the command line.
8function __fish_pacman_has_operation
9    set -l operations '-s D database' '-s Q query' '-s R remove' '-s S sync' '-s T deptest' '-s U upgrade' '-s F files'
10    if test (count $argv) -gt 0
11        set operations (string match -er (string join '|' -- $argv) -- $operations)
12    end
13    __fish_contains_opt (string split ' ' -- $operations)
14end
15
16function __fish_pacman_print_package_groups
17    argparse i/installed -- $argv
18    or return 1
19
20    set -l groups
21    if not set -q _flag_installed
22        set -a groups (pacman -Sg)
23    else
24        set -a groups (pacman -Qg | string split -f 1 ' ' | uniq)
25    end
26    printf '%s\n' $groups\t'Package Group'
27end
28
29# Used for pacman -F, which only handles basenames and absolute paths.
30function __fish_pacman_complete_absolute_paths
31    set -l target (commandline -ct)
32
33    if string match -q '/*' -- $target
34        __fish_complete_path $target
35    else if test -z $target
36        printf '%s\n' ''\t'Filename' /\t'Absolute Path'
37    end
38end
39
40# Do a normal __fish_print_pacman_packages, unless the command line has "$repo/...".
41# In that case, no package would matched, so it searches for packages in that repo
42# instead.
43function __fish_pacman_complete_packages_from_repo
44    set -l repo (commandline -ct | string replace -fr '^([^/]+)/.*$' '$1')
45    __fish_print_pacman_packages --repo=$repo 2>/dev/null
46    if test -z "$repo"
47        printf '%s\n' (__fish_print_pacman_repos)/\t'Repository'
48    end
49end
50
51# See PKGEXT on https://man.archlinux.org/man/makepkg.conf.5
52set -l pkgexts (string match --all --regex '\S+' '
53    .pkg.tar.gz
54    .pkg.tar.bz2
55    .pkg.tar.xz
56    .pkg.tar.zst
57    .pkg.tar.lzo
58    .pkg.tar.lrz
59    .pkg.tar.lz4
60    .pkg.tar.lz
61    .pkg.tar.Z
62    .pkg.tar
63')
64
65# From https://rfc.archlinux.page/0032-arch-linux-ports/
66set -l linux_architectures '
67    x86_64
68    x86_64_v2
69    x86_64_v3
70    x86_64_v4
71    i486
72    i686
73    pentium4
74    aarch64
75    armv7h
76    riscv64
77    loong64
78'
79
80# Exactly one main operation needed
81complete -c $progname -f
82complete -c $progname -n 'not __fish_pacman_has_operation' -a -D -d 'Modify the package database' -f
83complete -c $progname -n 'not __fish_pacman_has_operation' -a -Q -d 'Query the package database' -f
84complete -c $progname -n 'not __fish_pacman_has_operation' -a -R -d 'Remove packages from the system' -f
85complete -c $progname -n 'not __fish_pacman_has_operation' -a -S -d 'Synchronize packages' -f
86complete -c $progname -n 'not __fish_pacman_has_operation' -a -T -d 'Check dependencies' -f
87complete -c $progname -n 'not __fish_pacman_has_operation' -a -U -d 'Add a package from a file or URL' -f
88complete -c $progname -n 'not __fish_pacman_has_operation' -a -F -d 'Query the files database' -f
89
90## OPERATIONS
91complete -c $progname -n 'not __fish_pacman_has_operation || __fish_pacman_has_operation D' -s D -l database -d 'Modify the package database' -f
92complete -c $progname -n 'not __fish_pacman_has_operation || __fish_pacman_has_operation Q' -s Q -l query -d 'Query the package database' -f
93complete -c $progname -n 'not __fish_pacman_has_operation || __fish_pacman_has_operation R' -s R -l remove -d 'Remove packages from the system' -f
94complete -c $progname -n 'not __fish_pacman_has_operation || __fish_pacman_has_operation S' -s S -l sync -d 'Synchronize packages' -f
95complete -c $progname -n 'not __fish_pacman_has_operation || __fish_pacman_has_operation T' -s T -l deptest -d 'Check dependencies' -f
96complete -c $progname -n 'not __fish_pacman_has_operation || __fish_pacman_has_operation U' -s U -l upgrade -d 'Add a package from a file or URL' -f
97complete -c $progname -n 'not __fish_pacman_has_operation || __fish_pacman_has_operation F' -s F -l files -d 'Query the files database' -f
98complete -c $progname -s V -l version -d 'Display version and exit' -f
99complete -c $progname -s h -l help -d 'Display help' -f
100
101## OPTIONS
102# Only offer these once a command has been given so they get prominent display
103complete -c $progname -n __fish_pacman_has_operation -s b -l dbpath -d 'Alternate database location' -xa '(__fish_complete_directories)'
104complete -c $progname -n __fish_pacman_has_operation -s r -l root -d 'Alternate installation root' -xa '(__fish_complete_directories)'
105complete -c $progname -n __fish_pacman_has_operation -s v -l verbose -d 'Output paths of config files' -f
106complete -c $progname -n __fish_pacman_has_operation -l arch -d 'Alternate architecture' -xa $linux_architectures
107complete -c $progname -n __fish_pacman_has_operation -l cachedir -d 'Alternate package cache location' -xa '(__fish_complete_directories)'
108complete -c $progname -n __fish_pacman_has_operation -l color -d 'Colorize the output' -fa 'auto always never'
109complete -c $progname -n __fish_pacman_has_operation -l config -d 'Alternate config file' -xka '(__fish_complete_suffix .conf)'
110complete -c $progname -n __fish_pacman_has_operation -l debug -d 'Display debug messages' -f
111complete -c $progname -n __fish_pacman_has_operation -l gpgdir -d 'Alternate home directory for GnuPG' -xa '(__fish_complete_directories)'
112complete -c $progname -n __fish_pacman_has_operation -l hookdir -d 'Alternate hook location' -xa '(__fish_complete_directories)'
113complete -c $progname -n __fish_pacman_has_operation -l logfile -d 'Alternate log file' -rF
114complete -c $progname -n __fish_pacman_has_operation -l noconfirm -d 'Bypass any confirmation' -f
115complete -c $progname -n __fish_pacman_has_operation -l confirm -d 'Cancels a previous --noconfirm' -f
116complete -c $progname -n __fish_pacman_has_operation -l disable-download-timeout -d 'Use relaxed timeouts for download' -f
117complete -c $progname -n __fish_pacman_has_operation -l sysroot -d 'Operate on a mounted guest system (root-only)' -xa '(__fish_complete_directories)'
118complete -c $progname -n __fish_pacman_has_operation -l disable-sandbox -d '--disable-sandbox-filesystem and --disable-sandbox-syscalls' -f
119complete -c $progname -n __fish_pacman_has_operation -l disable-sandbox-filesystem -d 'Disable the filesystem restrictions' -f
120complete -c $progname -n __fish_pacman_has_operation -l disable-sandbox-syscalls -d 'Disable the syscall filtering' -f
121
122## TRANSACTION OPTIONS (APPLY TO -S, -R AND -U)
123complete -c $progname -n '__fish_pacman_has_operation S R U' -s d -l nodeps -d 'Skip [all] dependency checks' -f
124complete -c $progname -n '__fish_pacman_has_operation S R U' -l assume-installed -d 'Add a virtual package to satisfy dependencies' -xa '(__fish_print_pacman_packages)'
125complete -c $progname -n '__fish_pacman_has_operation S R U' -l dbonly -d 'Modify database entry only' -f
126complete -c $progname -n '__fish_pacman_has_operation S R U' -l noprogressbar -d 'Do not display progress bar' -f
127complete -c $progname -n '__fish_pacman_has_operation S R U' -l noscriptlet -d 'Do not execute install script' -f
128complete -c $progname -n '__fish_pacman_has_operation S R U' -s p -l print -d 'Dry run, only print targets' -f
129complete -c $progname -n '__fish_pacman_has_operation S R U' -l print-format -d 'Specify printf-like format' -x
130
131## UPGRADE OPTIONS (APPLY TO -S AND -U)
132complete -c $progname -n '__fish_pacman_has_operation S U' -s w -l downloadonly -d 'Retrieve packages but do not install' -f
133complete -c $progname -n '__fish_pacman_has_operation S U' -l asdeps -d 'Install packages as non-explicitly installed' -f
134complete -c $progname -n '__fish_pacman_has_operation S U' -l asexplicit -d 'Install packages as explicitly installed' -f
135complete -c $progname -n '__fish_pacman_has_operation S U' -l ignore -d 'Ignore a package upgrade (can be used more than once)' -xa '(__fish_print_pacman_packages)'
136complete -c $progname -n '__fish_pacman_has_operation S U' -l ignoregroup -d 'Ignore a group upgrade (can be used more than once)' -xa '(__fish_pacman_print_package_groups)'
137complete -c $progname -n '__fish_pacman_has_operation S U' -l needed -d 'Do not reinstall up to date packages' -f
138complete -c $progname -n '__fish_pacman_has_operation S U' -l overwrite -d 'Overwrite conflicting files (can be used more than once)' -rF
139
140## QUERY OPTIONS (APPLY TO -Q)
141complete -c $progname -n '__fish_pacman_has_operation Q' -s c -l changelog -d 'View the ChangeLog of PACKAGE' -f
142complete -c $progname -n '__fish_pacman_has_operation Q' -s d -l deps -d 'List only non-explicit packages (dependencies)' -f
143complete -c $progname -n '__fish_pacman_has_operation Q' -s e -l explicit -d 'List only explicitly installed packages' -f
144complete -c $progname -n '__fish_pacman_has_operation Q' -s g -l groups -d 'List only packages that are part of a group' -f
145complete -c $progname -n '__fish_pacman_has_operation Q' -s i -l info -d 'View PACKAGE [backup files] information' -f
146complete -c $progname -n '__fish_pacman_has_operation Q' -s k -l check -d 'Check that PACKAGE files exist' -f
147complete -c $progname -n '__fish_pacman_has_operation Q' -s l -l list -d 'List the files owned by PACKAGE' -f
148complete -c $progname -n '__fish_pacman_has_operation Q' -s m -l foreign -d 'List installed packages not found in sync database' -f
149complete -c $progname -n '__fish_pacman_has_operation Q' -s n -l native -d 'List installed packages only found in sync database' -f
150complete -c $progname -n '__fish_pacman_has_operation Q' -s o -l owns -d 'Query for packages that own FILE' -f
151complete -c $progname -n '__fish_pacman_has_operation Q' -s p -l file -d 'Query a package file instead of the database' -f
152complete -c $progname -n '__fish_pacman_has_operation Q' -s q -l quiet -d 'Show less information' -f
153complete -c $progname -n '__fish_pacman_has_operation Q' -s s -l search -d 'Search locally-installed packages for regexp' -f
154complete -c $progname -n '__fish_pacman_has_operation Q' -s t -l unrequired -d 'List only unrequired packages [and optdepends]' -f
155complete -c $progname -n '__fish_pacman_has_operation Q' -s u -l upgrades -d 'List only out-of-date packages' -f
156complete -c $progname -n '__fish_pacman_has_operation Q' -n 'not __fish_contains_opt -s g groups -s o owns -s p file' -d Package -xa '(__fish_print_pacman_packages --installed)'
157complete -c $progname -n '__fish_pacman_has_operation Q' -n '__fish_contains_opt -s g groups' -d 'Package Group' -xa '(__fish_pacman_print_package_groups --installed)'
158complete -c $progname -n '__fish_pacman_has_operation Q' -n '__fish_contains_opt -s o owns' -d File -rF
159complete -c $progname -n '__fish_pacman_has_operation Q' -n '__fish_contains_opt -s p file' -d 'Package File' -xka "(__fish_complete_suffix $pkgexts)"
160
161## REMOVE OPTIONS (APPLY TO -R)
162complete -c $progname -n '__fish_pacman_has_operation R' -s c -l cascade -d 'Also remove packages depending on PACKAGE' -f
163complete -c $progname -n '__fish_pacman_has_operation R' -s n -l nosave -d 'Ignore file backup designations' -f
164complete -c $progname -n '__fish_pacman_has_operation R' -s s -l recursive -d 'Also remove dependencies of PACKAGE' -f
165complete -c $progname -n '__fish_pacman_has_operation R' -s u -l unneeded -d 'Remove targets not required by any package' -f
166complete -c $progname -n '__fish_pacman_has_operation R' -d Package -xa '(__fish_print_pacman_packages --installed)'
167complete -c $progname -n '__fish_pacman_has_operation R' -d 'Package Group' -xa '(__fish_pacman_print_package_groups --installed)'
168
169## SYNC OPTIONS (APPLY TO -S)
170complete -c $progname -n '__fish_pacman_has_operation S' -s c -l clean -d 'Remove [all] packages from cache' -f
171complete -c $progname -n '__fish_pacman_has_operation S' -s g -l groups -d 'Display members of [all] package GROUP' -f
172complete -c $progname -n '__fish_pacman_has_operation S' -s i -l info -d 'View PACKAGE [extended] information' -f
173complete -c $progname -n '__fish_pacman_has_operation S' -s l -l list -d 'List all packages in REPOSITORY' -f
174complete -c $progname -n '__fish_pacman_has_operation S' -s q -l quiet -d 'Show less information' -f
175complete -c $progname -n '__fish_pacman_has_operation S' -s s -l search -d 'Search remote repositories for regexp' -f
176complete -c $progname -n '__fish_pacman_has_operation S' -s u -l sysupgrade -d 'Upgrade all packages that are out of date' -f
177complete -c $progname -n '__fish_pacman_has_operation S' -s y -l refresh -d 'Download fresh package databases [force]' -f
178complete -c $progname -n '__fish_pacman_has_operation S' -n 'not __fish_contains_opt -s g groups -s l list' -d Package -xa '(__fish_pacman_complete_packages_from_repo)'
179complete -c $progname -n '__fish_pacman_has_operation S' -n '__fish_contains_opt -s g groups' -d 'Package Group' -xa '(__fish_pacman_print_package_groups)'
180complete -c $progname -n '__fish_pacman_has_operation S' -n '__fish_contains_opt -s l list' -d Repository -xa '(__fish_print_pacman_repos)'
181
182## DATABASE OPTIONS (APPLY TO -D)
183complete -c $progname -n '__fish_pacman_has_operation D' -l asdeps -d 'Mark PACKAGE as dependency' -f
184complete -c $progname -n '__fish_pacman_has_operation D' -l asexplicit -d 'Mark PACKAGE as explicitly installed' -f
185complete -c $progname -n '__fish_pacman_has_operation D' -s k -l check -d 'Check database validity' -f
186complete -c $progname -n '__fish_pacman_has_operation D' -s q -l quiet -d 'Suppress output of success messages' -f
187complete -c $progname -n '__fish_pacman_has_operation D' -n '__fish_contains_opt asdeps asexplicit' -d Package -xa '(__fish_print_pacman_packages --installed)'
188
189## FILE OPTIONS (APPLY TO -F)
190complete -c $progname -n '__fish_pacman_has_operation F' -s y -l refresh -d 'Download fresh package databases [force]' -f
191complete -c $progname -n '__fish_pacman_has_operation F' -s l -l list -d 'List the files owned by PACKAGE' -f
192complete -c $progname -n '__fish_pacman_has_operation F' -s x -l regex -d 'Interpret each query as a regular expression' -f
193complete -c $progname -n '__fish_pacman_has_operation F' -s q -l quiet -d 'Show less information' -f
194complete -c $progname -n '__fish_pacman_has_operation F' -l machinereadable -d 'Print each match in a machine readable output format' -f
195complete -c $progname -n '__fish_pacman_has_operation F' -n '__fish_contains_opt -s l list' -d Package -xa '(__fish_print_pacman_packages)'
196complete -c $progname -n '__fish_pacman_has_operation F' -n 'not __fish_contains_opt -s l list' -d File -xa '(__fish_pacman_complete_absolute_paths)'
197
198# No extra options (-U)
199complete -c $progname -n '__fish_pacman_has_operation U' -d 'Package File' -xka "(__fish_complete_suffix $pkgexts)"