fork/fish-shell

git clone https://git.julia.blue/fork/fish-shell

Tiago de Paulacompletion/quilt: list predefined spec filters4fde7e4f2

master
24.7 KiB348 linesraw
1# completions for quilt version 0.69
2
3# List all patches in series, from latest to oldest (requires '-k').
4function __fish_quilt_print_series
5    set -l series (quilt series 2> /dev/null)
6    printf '%s\n' $series[-1..1]
7end
8
9# Suggest '$token.patch' and '$token.diff' as names for new patches.
10# An optional prefix can be passed to be removed from the patch name,
11# e.g `__fish_quilt_complete_patch_name -p '-z'` for `quilt refresh -z[new_name]`.
12function __fish_quilt_complete_patch_name -a prefix
13    argparse --move-unknown 'p/prefix=&' -- $argv
14    or return 1
15
16    set -l name (commandline -ct)
17    if test -z $name -o $name = "$_flag_prefix"
18        return 1
19    end
20
21    printf '%s\n' $name
22    set -l suggestions
23    # output successful replace before other suggestions, requires '-k' to work
24    if not string replace --filter --regex '\.(d(i(f(f)?)?)?)?$' '.diff' -- $name
25        set -a suggestions $name.diff
26    end
27    if not string replace --filter --regex '\.(p(a(t(c(h)?)?)?)?)?$' '.patch' -- $name
28        set -a suggestions $name.patch
29    end
30    printf '%s\n' $suggestions
31    return 0
32end
33
34# For `quilt refresh -z[new_name]`, which looks like a short option
35# but needs an argument connected to the switch.
36function __fish_quilt_current_zarg -a quiet
37    string match $quiet --regex '^-\w*z' -- (commandline -ct)
38end
39
40# Suggest more digits in number. Most useful for diff context and
41# other options with a low number of digits.
42function __fish_quilt_complete_integer
43    set token (commandline -ct)
44    if string match --quiet --regex '^\d*$' -- $token
45        printf '%s\n' $token $token(seq 0 9)
46    end
47end
48
49# Forward completions of 'quilt grep ...' to grep itself.
50function __fish_quilt_complete_grep
51    set -l command (commandline -px)
52    while test (count $command) -gt 0 -a $command[1] != grep
53        set -e command[1]
54    end
55
56    set -l arguments $command[2..]
57    # quilt captures the initial -h arguments
58    set -l quilt_help -h
59    while test "$arguments[1]" = $quilt_help
60        set -e arguments[1]
61    end
62    # and the first -- to stop capturing -h
63    set -l quilt_sentinel --
64    if test "$arguments[1]" = $quilt_sentinel
65        set -e arguments[1]
66    end
67
68    complete -C "grep $(string escape -- $arguments)"
69end
70
71# List options for 'quilt setup --spec-filter ...'.
72function __fish_quilt_complete_spec_filters
73    # the current $QUILTRC can be safely ignored, since $QUILT_DIR is read before that
74    set -l quilt_dir (quilt --quiltrc (echo 'printf "%s\n" "${QUILT_DIR}"' | psub) top -h 2>/dev/null | head -n 1)
75
76    printf '%s\n' (path basename $quilt_dir/spec-filters/*)\t'Predefined Filter'
77    printf '%s\n' (__fish_complete_path (commandline -ct))\t'Custom Filter'
78end
79
80complete -c quilt -f
81
82# quilt [command] -h
83set -l commands (string match --all --regex '\S+' '
84    add
85    annotate
86    applied
87    delete
88    diff
89    edit
90    files
91    fold
92    fork
93    graph
94    grep
95    header
96    import
97    mail
98    new
99    next
100    patches
101    pop
102    previous
103    push
104    refresh
105    remove
106    rename
107    revert
108    series
109    setup
110    snapshot
111    top
112    unapplied
113    upgrade
114')
115complete -c quilt -n "__fish_seen_subcommand_from $commands" -s h -d 'Show help' -f
116
117# quilt [--quiltrc file] [--trace] command [options]
118complete -c quilt -n "not __fish_seen_subcommand_from $commands" -l quiltrc -d 'Config file to use' -xka "(__fish_complete_suffix --description=Config .rc quiltrc) -\t'No config'"
119complete -c quilt -n "not __fish_seen_subcommand_from $commands" -l trace -d 'Trace internal shell commands (bash -x)' -fa verbose
120
121# quilt --version
122complete -c quilt -n "not __fish_seen_subcommand_from $commands" -l version -d 'Show version' -f
123
124# quilt add [-P patch] {file} ...
125complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a add -d 'Add files to patch' -f
126complete -c quilt -n '__fish_seen_subcommand_from add' -s P -d 'Patch to add files to' -xka '(__fish_quilt_print_series)'
127complete -c quilt -n '__fish_seen_subcommand_from add' -rF
128
129# quilt annotate [-P patch] {file}
130complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a annotate -d 'Show which patches modify which lines in file' -f
131complete -c quilt -n '__fish_seen_subcommand_from annotate' -s P -d 'Stop checking for changes at the specified patch' -xka '(__fish_quilt_print_series)'
132complete -c quilt -n '__fish_seen_subcommand_from annotate' -rF
133
134# quilt applied [patch]
135complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a applied -d 'List applied patches in the stack' -f
136complete -c quilt -n '__fish_seen_subcommand_from applied' -d 'Up to and including' -fka '(__fish_quilt_print_series)'
137
138# quilt delete [-r] [--backup] [patch|-n]
139complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a delete -d 'Remove patch from the series' -f
140complete -c quilt -n '__fish_seen_subcommand_from delete' -s r -d 'Remove patch file from the patches directory as well' -f
141complete -c quilt -n '__fish_seen_subcommand_from delete' -l backup -d 'Rename the patch file to patch~' -f
142complete -c quilt -n '__fish_seen_subcommand_from delete' -s n -d 'Delete the next patch after topmost' -f
143complete -c quilt -n '__fish_seen_subcommand_from delete' -n 'not __fish_seen_argument -s n' -d 'Patch to remove' -fka '(__fish_quilt_print_series)'
144
145# quilt diff [-p n|-p ab] [-u|-U num|-c|-C num] [--combine patch|-z] [-R] [-P patch] [--snapshot] [--diff=utility] [--no-timestamps] [--no-index] [--sort] [--color[=always|auto|never]] [file ...]
146complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a diff -d 'Diff files in patch' -f
147complete -c quilt -n '__fish_seen_subcommand_from diff' -s p -d 'File name style in patch' -xa '0\t"-p0 patch" 1\t"-p1 patch" ab\t"-p1 patch with a/file b/file"'
148complete -c quilt -n '__fish_seen_subcommand_from diff' -s u -d 'Unified diff (3 lines of context)' -f
149complete -c quilt -n '__fish_seen_subcommand_from diff' -s U -d 'Unified diff (N lines of context)' -xa '(__fish_quilt_complete_integer)'
150complete -c quilt -n '__fish_seen_subcommand_from diff' -s c -d 'Context diff (3 lines of context)' -f
151complete -c quilt -n '__fish_seen_subcommand_from diff' -s C -d 'Context diff (N lines of context)' -xa '(__fish_quilt_complete_integer)'
152complete -c quilt -n '__fish_seen_subcommand_from diff' -l combine -d 'Combined diff between this patch and -P' -xka "(__fish_quilt_print_series)\t'First patch to combine'"
153complete -c quilt -n '__fish_seen_subcommand_from diff' -s z -d 'Write to stdout' -f
154complete -c quilt -n '__fish_seen_subcommand_from diff' -s R -d 'Reverse diff' -f
155complete -c quilt -n '__fish_seen_subcommand_from diff' -s P -d 'Patch to diff' -xka '(__fish_quilt_print_series)'
156complete -c quilt -n '__fish_seen_subcommand_from diff' -l snapshot -d 'Diff against snapshot' -f
157complete -c quilt -n '__fish_seen_subcommand_from diff' -l diff -d 'Custom diff command' -xa '(__fish_complete_command)'
158complete -c quilt -n '__fish_seen_subcommand_from diff' -l no-timestamps -d 'Do not include timestamps in headers' -f
159complete -c quilt -n '__fish_seen_subcommand_from diff' -l no-index -d "Do not include 'Index: lines' in headers" -f
160complete -c quilt -n '__fish_seen_subcommand_from diff' -l sort -d 'Sort files by name' -f
161complete -c quilt -n '__fish_seen_subcommand_from diff' -l color -d 'Use syntax coloring' -fa 'always auto never'
162complete -c quilt -n '__fish_seen_subcommand_from diff' -F
163
164# quilt edit file ...
165complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a edit -d 'Edit files in $EDITOR' -f
166complete -c quilt -n '__fish_seen_subcommand_from edit' -rF
167
168# quilt files [-v] [-a] [-l] [--combine patch] [patch]
169complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a files -d 'Lists files changed by patch' -f
170complete -c quilt -n '__fish_seen_subcommand_from files' -s v -d 'Pretty output' -f
171complete -c quilt -n '__fish_seen_subcommand_from files' -s a -d 'List all files in all applied patches' -f
172complete -c quilt -n '__fish_seen_subcommand_from files' -s l -d 'Add patch name to output' -f
173complete -c quilt -n '__fish_seen_subcommand_from files' -l combine -d 'Combined listing between this patch and -P' -xka '(__fish_quilt_print_series)'
174complete -c quilt -n '__fish_seen_subcommand_from files' -d 'List files changed by patch' -fka '(__fish_quilt_print_series)'
175
176# quilt fold [-R] [-q] [-f] [-p strip-level]
177complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a fold -d 'Integrate patch from stdin into the topmost patch' -f
178complete -c quilt -n '__fish_seen_subcommand_from fold' -s R -d 'Apply patch in reverse' -f
179complete -c quilt -n '__fish_seen_subcommand_from fold' -s q -d 'Quiet operation' -f
180complete -c quilt -n '__fish_seen_subcommand_from fold' -s f -d 'Force apply, even if the patch has rejects' -f
181complete -c quilt -n '__fish_seen_subcommand_from fold' -s p -d 'Number of components to strip from paths' -xa '(__fish_quilt_complete_integer)'
182
183# quilt fork [new_name]
184complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a fork -d 'Fork the topmost patch' -f
185complete -c quilt -n '__fish_seen_subcommand_from fork' -fka '(__fish_quilt_complete_patch_name)'
186
187# quilt graph [--all] [--reduce] [--lines[=num]] [--edge-labels=files] [-T ps] [patch]
188complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a graph -d 'Visualize patch dependencies using dot' -f
189complete -c quilt -n '__fish_seen_subcommand_from graph' -l all -d 'Include all applied patches and their dependencies' -f
190complete -c quilt -n '__fish_seen_subcommand_from graph' -l reduce -d 'Eliminate transitive edges from the graph' -f
191complete -c quilt -n '__fish_seen_subcommand_from graph' -l lines -d 'Compute dependencies by the lines the patches modify' -fa '(__fish_quilt_complete_integer)'
192complete -c quilt -n '__fish_seen_subcommand_from graph' -l edge-labels -d 'Label graph edges with the file names' -xa files
193complete -c quilt -n '__fish_seen_subcommand_from graph' -s T -d 'Directly produce a PostScript output file' -xa ps
194complete -c quilt -n '__fish_seen_subcommand_from graph' -n 'not __fish_seen_argument -l all' -d 'Patch to graph dependencies' -fka '(__fish_quilt_print_series)'
195
196# quilt grep [-h|options] {pattern}
197complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a grep -d 'Search through source files' -f
198complete -c quilt -n '__fish_seen_subcommand_from grep' -fa '(__fish_quilt_complete_grep)'
199
200# quilt header [-a|-r|-e] [--backup] [--strip-diffstat] [--strip-trailing-whitespace] [patch]
201complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a header -d 'Print/change the header of patch' -f
202complete -c quilt -n '__fish_seen_subcommand_from header' -n 'not __fish_seen_argument -s a -s r -s e' -s a -d 'Append to patch header' -f
203complete -c quilt -n '__fish_seen_subcommand_from header' -n 'not __fish_seen_argument -s a -s r -s e' -s r -d 'Replace patch header' -f
204complete -c quilt -n '__fish_seen_subcommand_from header' -n 'not __fish_seen_argument -s a -s r -s e' -s e -d 'Edit header in $EDITOR' -f
205complete -c quilt -n '__fish_seen_subcommand_from header' -l backup -d 'Rename old version of a patch as patch~' -f
206complete -c quilt -n '__fish_seen_subcommand_from header' -l strip-diffstat -d 'Remove diffstat from the header' -f
207complete -c quilt -n '__fish_seen_subcommand_from header' -l strip-trailing-whitespace -d 'Strip whitespace at the end of lines' -f
208complete -c quilt -n '__fish_seen_subcommand_from header' -d 'Print/change header of patch' -fka '(__fish_quilt_print_series)'
209
210# quilt import [-p num] [-R] [-P patch] [-f] [-d {o|a|n}] patchfile ...
211complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a import -d 'Import external patches' -f
212complete -c quilt -n '__fish_seen_subcommand_from import' -s p -d 'Number of directories to strip' -xa '(__fish_quilt_complete_integer)'
213complete -c quilt -n '__fish_seen_subcommand_from import' -s R -d 'Apply patch in reverse' -f
214complete -c quilt -n '__fish_seen_subcommand_from import' -s P -d 'Patch filename to use inside quilt' -xka '(__fish_quilt_complete_patch_name)'
215complete -c quilt -n '__fish_seen_subcommand_from import' -s f -d 'Overwrite/update existing patches' -f
216complete -c quilt -n '__fish_seen_subcommand_from import' -s d -d 'Which header to keep on overwrite' -xa "o\t'Keep old header' a\t'Keep all headers' n\t'Keep new header'"
217complete -c quilt -n '__fish_seen_subcommand_from import' -d 'Patch to import' -fa '(__fish_complete_suffix .patch .diff)'
218
219# quilt mail {--mbox file|--send} [-m text] [-M file] [--prefix prefix] [--sender ...] [--from ...] [--to ...] [--cc ...] [--bcc ...] [--subject ...] [--reply-to message] [--charset ...] [--signature file] [first_patch [last_patch]]
220complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a mail -d 'Create or send mail messages from patches' -f
221complete -c quilt -n '__fish_seen_subcommand_from mail' -l mbox -d 'Store the messages in an MBox file' -rF
222complete -c quilt -n '__fish_seen_subcommand_from mail' -l send -d 'Send the messages directly' -f
223complete -c quilt -n '__fish_seen_subcommand_from mail' -s m -d 'Text to use in the introduction' -x
224complete -c quilt -n '__fish_seen_subcommand_from mail' -s M -d 'Read the introduction from file' -x
225complete -c quilt -n '__fish_seen_subcommand_from mail' -l prefix -d 'Alternate bracketed prefix for the subject' -x
226complete -c quilt -n '__fish_seen_subcommand_from mail' -l sender -d 'The envelope sender address to use' -x
227complete -c quilt -n '__fish_seen_subcommand_from mail' -l from -d 'Value for the From header' -x
228complete -c quilt -n '__fish_seen_subcommand_from mail' -l to -d 'Append recipient in the To header' -x
229complete -c quilt -n '__fish_seen_subcommand_from mail' -l cc -d 'Append recipient in the Cc header' -x
230complete -c quilt -n '__fish_seen_subcommand_from mail' -l bcc -d 'Append recipient in the Bcc header' -x
231complete -c quilt -n '__fish_seen_subcommand_from mail' -l subject -d 'Value for the From header' -x
232complete -c quilt -n '__fish_seen_subcommand_from mail' -l reply-to -d 'Add headers to reply to the message' -x
233complete -c quilt -n '__fish_seen_subcommand_from mail' -l charset -d 'Specify a message encoding' -xa '(__fish_print_encodings)'
234complete -c quilt -n '__fish_seen_subcommand_from mail' -l signature -d 'Append the signature to message' -rF
235complete -c quilt -n '__fish_seen_subcommand_from mail' -n 'not __fish_seen_argument -l mbox -l send' -a -mbox -d 'Store the messages in an MBox file' -f
236complete -c quilt -n '__fish_seen_subcommand_from mail' -n 'not __fish_seen_argument -l mbox -l send' -a -send -d 'Send the messages directly' -f
237complete -c quilt -n '__fish_seen_subcommand_from mail' -n 'test (__fish_number_of_cmd_args_wo_opts) -eq 2' -d 'First patch to include' -fka '(__fish_quilt_print_series)'
238complete -c quilt -n '__fish_seen_subcommand_from mail' -n 'test (__fish_number_of_cmd_args_wo_opts) -eq 3' -d 'Last patch to include' -fka '(__fish_quilt_print_series)'
239
240# quilt new [-p n] {patchname}
241complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a new -d 'Start a new topmost patch' -f
242complete -c quilt -n '__fish_seen_subcommand_from new' -s p -d 'File name style in patch' -xa "0\t'-p0 patch' 1\t'-p1 patch'"
243complete -c quilt -n '__fish_seen_subcommand_from new' -xka '(__fish_quilt_complete_patch_name)'
244
245# quilt next [patch]
246complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a next -d 'Name of patch after the topmost/given patch' -f
247complete -c quilt -n '__fish_seen_subcommand_from next' -xka '(__fish_quilt_print_series)'
248
249# quilt patches [-v] [--color[=always|auto|never]] {file} [files...]
250complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a patches -d 'List patches that modify the file(s)' -f
251complete -c quilt -n '__fish_seen_subcommand_from patches' -s v -d 'Pretty output' -f
252complete -c quilt -n '__fish_seen_subcommand_from patches' -l color -d 'Use syntax coloring' -fa 'always auto never'
253complete -c quilt -n '__fish_seen_subcommand_from patches' -rF
254
255# quilt pop [-afRqv] [--refresh] [num|patch]
256complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a pop -d 'Unapply patches from the stack' -f
257complete -c quilt -n '__fish_seen_subcommand_from pop' -s a -d 'Remove all applied patches' -f
258complete -c quilt -n '__fish_seen_subcommand_from pop' -s f -d 'Force remove and restore state from backup files' -f
259complete -c quilt -n '__fish_seen_subcommand_from pop' -s R -d 'Always verify if the patch removes cleanly' -f
260complete -c quilt -n '__fish_seen_subcommand_from pop' -s q -d 'Quiet operation' -f
261complete -c quilt -n '__fish_seen_subcommand_from pop' -s v -d 'Verbose operation' -f
262complete -c quilt -n '__fish_seen_subcommand_from pop' -l refresh -d 'Refresh every patch before it gets unapplied' -f
263complete -c quilt -n '__fish_seen_subcommand_from pop' -n 'not __fish_seen_argument -s a' -d 'Pop N patches' -fka '(seq 1 (count (__fish_quilt_print_series)))'
264complete -c quilt -n '__fish_seen_subcommand_from pop' -n 'not __fish_seen_argument -s a' -d 'Pop down to' -fka '(__fish_quilt_print_series)'
265
266# quilt previous [patch]
267complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a previous -d 'Name of patch before the topmost/given patch' -f
268complete -c quilt -n '__fish_seen_subcommand_from previous' -d 'Target patch' -fka '(__fish_quilt_print_series)'
269
270# quilt push [-afqvm] [--fuzz=N] [--merge[=merge|diff3]] [--leave-rejects] [--color[=always|auto|never]] [--refresh] [num|patch]
271complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a push -d 'Apply patches from the series' -f
272complete -c quilt -n '__fish_seen_subcommand_from push' -s a -d 'Apply all patches in the series file' -f
273complete -c quilt -n '__fish_seen_subcommand_from push' -s f -d 'Force apply, even if the patch has rejects' -f
274complete -c quilt -n '__fish_seen_subcommand_from push' -s q -d 'Quiet operation' -f
275complete -c quilt -n '__fish_seen_subcommand_from push' -s v -d 'Verbose operation' -f
276complete -c quilt -n '__fish_seen_subcommand_from push' -s m -d 'Merge the patch file into the original files' -f
277complete -c quilt -n '__fish_seen_subcommand_from push' -l merge -d 'Merge the patch file into the original files' -fa 'merge diff3'
278complete -c quilt -n '__fish_seen_subcommand_from push' -l fuzz -d 'Maximum fuzz factor (in lines)' -xa '(__fish_quilt_complete_integer)'
279complete -c quilt -n '__fish_seen_subcommand_from push' -l leave-rejects -d 'Leave around the reject files patch produced' -f
280complete -c quilt -n '__fish_seen_subcommand_from push' -l color -d 'Use syntax coloring' -fa 'always auto never'
281complete -c quilt -n '__fish_seen_subcommand_from push' -l refresh -d 'Automatically refresh every patch after it gets applied' -f
282complete -c quilt -n '__fish_seen_subcommand_from push' -n 'not __fish_seen_argument -s a' -d 'Apply N patches' -fka '(seq 1 (count (__fish_quilt_print_series)))'
283complete -c quilt -n '__fish_seen_subcommand_from push' -n 'not __fish_seen_argument -s a' -d 'Apply up to' -fka '(__fish_quilt_print_series)'
284
285# quilt refresh [-p n|-p ab] [-u|-U num|-c|-C num] [-z[new_name]] [-f] [--no-timestamps] [--no-index] [--diffstat] [--sort] [--backup] [--strip-trailing-whitespace] [patch]
286complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a refresh -d 'Update patch with changes from source' -f
287complete -c quilt -n '__fish_seen_subcommand_from refresh' -n 'not __fish_quilt_current_zarg -q' -s p -d 'File name style in patch' -xa "0\t'-p0 patch' 1\t'-p1 patch' ab\t'-p1 patch with a/file b/file'"
288complete -c quilt -n '__fish_seen_subcommand_from refresh' -n 'not __fish_quilt_current_zarg -q' -s u -d 'Unified diff (3 lines of context)' -f
289complete -c quilt -n '__fish_seen_subcommand_from refresh' -n 'not __fish_quilt_current_zarg -q' -s U -d 'Unified diff (N lines of context)' -xa '(__fish_quilt_complete_integer)'
290complete -c quilt -n '__fish_seen_subcommand_from refresh' -n 'not __fish_quilt_current_zarg -q' -s c -d 'Context diff (3 lines of context)' -f
291complete -c quilt -n '__fish_seen_subcommand_from refresh' -n 'not __fish_quilt_current_zarg -q' -s C -d 'Context diff (N lines of context)' -xa '(__fish_quilt_complete_integer)'
292complete -c quilt -n '__fish_seen_subcommand_from refresh' -n 'not __fish_quilt_current_zarg -q' -s z -d 'Create a new patch with the changes' -x
293complete -c quilt -n '__fish_seen_subcommand_from refresh' -n '__fish_quilt_current_zarg -q' -d 'Name of the new patch' -xka "(__fish_quilt_complete_patch_name -p (__fish_quilt_current_zarg))"
294complete -c quilt -n '__fish_seen_subcommand_from refresh' -n '__fish_quilt_current_zarg -q' -s h -e
295complete -c quilt -n '__fish_seen_subcommand_from refresh' -n 'not __fish_quilt_current_zarg -q' -s f -d 'Refresh a patch that is not on top' -f
296complete -c quilt -n '__fish_seen_subcommand_from refresh' -l no-timestamps -d 'Do not include timestamps in header' -f
297complete -c quilt -n '__fish_seen_subcommand_from refresh' -l no-index -d "Do not include 'Index: lines' in header" -f
298complete -c quilt -n '__fish_seen_subcommand_from refresh' -l diffstat -d 'Add or replace diffstat section to header' -f
299complete -c quilt -n '__fish_seen_subcommand_from refresh' -l sort -d 'Sort files by name' -f
300complete -c quilt -n '__fish_seen_subcommand_from refresh' -l backup -d 'Rename old patch file to patch~' -f
301complete -c quilt -n '__fish_seen_subcommand_from refresh' -l strip-trailing-whitespace -d 'Strip whitespace at the end of lines' -f
302complete -c quilt -n '__fish_seen_subcommand_from refresh' -d 'Patch to refresh' -fka '(__fish_quilt_print_series)'
303
304# quilt remove [-P patch] {file} ...
305complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a remove -d 'Remove files from the patch' -f
306complete -c quilt -n '__fish_seen_subcommand_from remove' -s P -d 'Remove files from named patch' -xka '(__fish_quilt_print_series)'
307complete -c quilt -n '__fish_seen_subcommand_from remove' -rF
308
309# quilt rename [-P patch] new_name
310complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a rename -d 'Rename the topmost/given patch' -f
311complete -c quilt -n '__fish_seen_subcommand_from rename' -s P -d 'Patch to rename' -xka '(__fish_quilt_print_series)'
312complete -c quilt -n '__fish_seen_subcommand_from rename' -xka "(__fish_quilt_complete_patch_name)\t'Suggestion'"
313complete -c quilt -n '__fish_seen_subcommand_from rename' -xka "(__fish_quilt_print_series)\t'Old names'"
314
315# quilt revert [-P patch] {file} ...
316complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a revert -d 'Revert file changes in patch' -f
317complete -c quilt -n '__fish_seen_subcommand_from revert' -s P -d 'Revert changes in patch' -xka '(__fish_quilt_print_series)'
318complete -c quilt -n '__fish_seen_subcommand_from revert' -rF
319
320# quilt series [--color[=always|auto|never]] [-v]
321complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a series -d 'List all patches in the series' -f
322complete -c quilt -n '__fish_seen_subcommand_from series' -l color -d 'Use syntax coloring' -fa 'always auto never'
323complete -c quilt -n '__fish_seen_subcommand_from series' -s v -d 'Pretty output' -f
324
325# quilt setup [-d path-prefix] [-v] [--sourcedir dir] [--fuzz=N] [--spec-filter FILTER] [--slow|--fast] {specfile|seriesfile}
326complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a setup -d 'Initializes a source tree from an rpm spec or a quilt series' -f
327complete -c quilt -n '__fish_seen_subcommand_from setup' -s d -d 'Path prefix for the resulting source tree' -x
328complete -c quilt -n '__fish_seen_subcommand_from setup' -s v -d 'Verbose debug output' -f
329complete -c quilt -n '__fish_seen_subcommand_from setup' -l sourcedir -d 'Directory for package sources' -xa '(__fish_complete_directories)'
330complete -c quilt -n '__fish_seen_subcommand_from setup' -l fuzz -d 'Maximum fuzz factor (in lines)' -xa '(__fish_quilt_complete_integer)'
331complete -c quilt -n '__fish_seen_subcommand_from setup' -l spec-filter -d 'Apply a filter before passing the spec file to rpmbuild' -xa '(__fish_quilt_complete_spec_filters)'
332complete -c quilt -n '__fish_seen_subcommand_from setup' -n 'not __fish_seen_argument -l slow -l fast' -l slow -d 'Use original method to process the spec file' -f
333complete -c quilt -n '__fish_seen_subcommand_from setup' -n 'not __fish_seen_argument -l slow -l fast' -l fast -d 'Use new method to process the spec file' -f
334complete -c quilt -n '__fish_seen_subcommand_from setup' -xa '(__fish_complete_suffix .spec series)'
335
336# quilt snapshot [-d]
337complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a snapshot -d 'Take a snapshot of the working state' -f
338complete -c quilt -n '__fish_seen_subcommand_from snapshot' -s d -d 'Only remove current snapshot' -f
339
340# quilt top
341complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a top -d 'Name of topmost patch in the stack' -f
342
343# quilt unapplied [patch]
344complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a unapplied -d 'List unapplied patches in the series' -f
345complete -c quilt -n '__fish_seen_subcommand_from unapplied' -d 'Patch to assume as top' -fka '(__fish_quilt_print_series)'
346
347# quilt upgrade
348complete -c quilt -n "not __fish_seen_subcommand_from $commands" -a upgrade -d 'Upgrade meta-data from older version of quilt' -f