fork/fish-shell

git clone https://git.julia.blue/fork/fish-shell

Fabian BoehmRestyle16c2c14fb

master
4.8 KiB72 linesraw
1# abort if `rename` is not installed
2command -sq rename; or return
3
4set -l rename_version (rename --version 2>/dev/null)
5set -l version_status $status
6
7if string match -q "*util-linux*" $rename_version[1]
8    # util-linux version
9    # https://www.mankier.com/1/rename
10    complete -c rename -s s -l symlink -d 'Rename symlink target(s)'
11    complete -c rename -s v -l verbose -n '! __fish_seen_argument -s n -l no-act' -d 'Show which files were renamed'
12    complete -c rename -s v -l verbose -n '__fish_seen_argument -s n -l no-act' -d 'Show which files would be renamed'
13    complete -c rename -s n -l no-act -d 'Make no changes'
14    complete -c rename -s a -l all -d 'Replace all occurrences'
15    complete -c rename -s l -l last -d 'Replace only the last occurrence'
16    complete -c rename -s o -l no-overwrite -n '! __fish_seen_argument -s s -l symlink' -d "Don't overwrite existing files"
17    complete -c rename -s o -l no-overwrite -n '__fish_seen_argument -s s -l symlink' -d "Don't overwrite symlink targets"
18    complete -c rename -s i -l interactive -d 'Ask before overwriting'
19    complete -c rename -s h -l help -d 'Print help text and exit'
20    complete -c rename -s V -l version -d 'Print version and exit'
21else if string match -q "*File::Rename*" $rename_version[1]
22    # Perl library version
23    # https://metacpan.org/release/File-Rename
24    complete -c rename -s v -l verbose -d 'Print renamed files'
25    complete -c rename -s 0 -l null -d 'Split on NUL when reading from stdin'
26    complete -c rename -s n -l nono -d 'Only show what would be renamed'
27    complete -c rename -s f -l force -d 'Overwrite existing files'
28    complete -c rename -l path -l fullpath -n '! __fish_seen_argument -s d -l filename -l nopath -l nofullpath' -d 'Rename any directory component'
29    complete -c rename -s d -l filename -l nopath -l nofullpath -n '! __fish_seen_argument -l path -l fullpath' -d 'Rename only filename component'
30    complete -c rename -s h -l help -d 'Print synopsis and options'
31    complete -c rename -s m -l man -d 'Print manual page'
32    complete -c rename -s V -l version -d 'Show version number'
33    complete -c rename -s u -l unicode -d 'Treat filenames as Unicode strings'
34    complete -c rename -s e -x -d 'Perl expression'
35    complete -c rename -s E -x -d 'Perl statement'
36else if test "$version_status" = 2
37    # `brew install rename`
38    # http://plasmasturm.org/code/rename
39    complete -c rename -s h -l help -d 'See a synopsis'
40    complete -c rename -l man -d 'Browse the manpage'
41    complete -c rename -s 0 -l null -d 'Split on NUL bytes'
42    complete -c rename -s f -l force -d 'Rename over existing files'
43    complete -c rename -s g -l glob -d 'Glob filename arguments'
44    complete -c rename -s i -l interactive -d 'Confirm every action'
45    complete -c rename -s k -l backwards -l reverse-order -d 'Process last file first'
46    complete -c rename -s l -l symlink -n '! __fish_seen_argument -s L -l hardlink' -d 'Symlink instead of renaming'
47    complete -c rename -s L -l hardlink -n '! __fish_seen_argument -s l -l symlink' -d 'Hardlink instead of renaming'
48    complete -c rename -s M -l use -x -d 'Like perl -M'
49    complete -c rename -s n -l dry-run -l just-print -d 'Only show what would be renamed'
50    complete -c rename -s N -l counter-format -x -a '01 001 0001' -d 'Format and set $N per template'
51    complete -c rename -s p -l mkpath -l make-dirs -d 'Create non-existent dirs'
52    complete -c rename -l stdin -l no-stdin -d 'Always/never read list of files from STDIN'
53    complete -c rename -s T -l transcode -x -d 'Transcode filenames'
54    complete -c rename -s v -l verbose -d 'Print more information'
55    complete -c rename -s a -l append -x -d 'Append STRING to each filename'
56    complete -c rename -s A -l prepend -x -d 'Prepend STRING to each filename'
57    complete -c rename -s c -l lower-case -d 'Convert to all lowercase'
58    complete -c rename -s C -l upper-case -d 'Convert to all uppercase'
59    complete -c rename -s e -l expr -x -d 'Perl expression'
60    complete -c rename -s P -l pipe -d 'Pass filenames to external command'
61    complete -c rename -s s -l subst -x -d 'Simple text substitution'
62    complete -c rename -s S -l subst-all -x -d 'Like -s, but substitutes all matches'
63    complete -c rename -s x -l remove-extension -d 'Remove extension'
64    complete -c rename -s X -l keep-extension -d 'Save and remove extension'
65    complete -c rename -s z -l sanitize -d 'Shortcut for --nows --noctrl --nometa --trim'
66    complete -c rename -l camelcase -d 'Capitalise each word in the filename'
67    complete -c rename -l urlesc -d 'Decode URL-escaped filenames'
68    complete -c rename -l nows -d 'Replace all whitespace with underscores'
69    complete -c rename -l rews -d 'Replace all underscores with whitespace'
70    complete -c rename -l noctrl -d 'Replace all control chars with underscores'
71    complete -c rename -l nometa -d 'Replace all shell meta-chars with underscores'
72end