fork/fish-shell

git clone https://git.julia.blue/fork/fish-shell

Daniel Rainerformat: remove trailing whitespace7360deee7

master
1.5 KiB38 linesraw
1#Completions for rm
2if rm --version >/dev/null 2>/dev/null # GNU
3    complete -c rm -s d -l directory -d "Unlink directories"
4    complete -c rm -s f -l force -d "Never prompt for removal"
5    complete -c rm -s i -l interactive -d "Prompt for removal"
6    complete -c rm -s I -d "Prompt to remove >3 files"
7    complete -c rm -s r -l recursive -d "Recursively remove subdirs"
8    complete -c rm -s R -d "Recursively remove subdirs"
9    complete -c rm -s v -l verbose -d "Explain what is done"
10    complete -c rm -s h -l help -d "Display help"
11    complete -c rm -l version -d "Display rm version"
12else
13    set -l uname (uname -s)
14    # solaris:   rm [-fi        ] file ...
15    # openbsd:   rm [-fidPRrv   ] file ...
16    # macos:     rm [-fidPRrvW  ] file ...
17    # netbsd:    rm [-fidPRrvWx ] file ...
18    # freebsd:   rm [-fidPRrvWxI] file ...
19    # dragonfly: rm [-fidPRrvWxI] file ...
20
21    complete -c rm -s f -d "Never prompt for removal"
22    complete -c rm -s i -d "Prompt for removal"
23    test "$uname" = SunOS
24    and exit 0
25    complete -c rm -s d -d "Remove directories as well"
26    complete -c rm -s P -d "Overwrite before removal"
27    complete -c rm -s R -s r -d "Recursively remove subdirs"
28    complete -c rm -s v -d "Explain what is done"
29    test "$uname" = OpenBSD
30    and exit 0
31    complete -c rm -s W -d "Undelete given filenames"
32    test "$uname" = Darwin
33    and exit 0
34    complete -c rm -s x -d "Don't traverse mount points"
35    test "$uname" = NetBSD
36    and exit 0
37    complete -c rm -s I -d "Prompt to remove >=3 files"
38end