fork/fish-shell

git clone https://git.julia.blue/fork/fish-shell

Fabian BoehmReformat share/**.fish with newlines collapsed78c948282

master
3.6 KiB83 linesraw
1function __fish_detect_screen_socket_dir -d "Detect which folder screen uses"
2    set -l screen_bin screen
3    if not set -q __fish_screen_socket_dir
4        set -g __fish_screen_socket_dir ($screen_bin -ls __fish_i_don_t_think_this_will_be_matched | string match -r "(?<=No Sockets found in ).*(?=\.)")
5    end
6end
7
8function __fish_complete_screen_general_list_mac -d "Get the socket list on mac"
9    pushd $__fish_screen_socket_dir >/dev/null
10    set -l sockets (ls)
11    if test (count $sockets) -ne 0
12        switch $argv
13            case Detached
14                stat -f "%Lp %SB %N" -t "%D %T" $sockets | string match -r '^6\d{2} .*$' | string replace -r '^6\d{2} (\S+ \S+) (\S+)' '$2\t$1 Detached'
15            case Attached
16                stat -f "%Lp %SB %N" -t "%D %T" $sockets | string match -r '^7\d{2} .*$' | string replace -r '^7\d{2} (\S+ \S+) (\S+)' '$2\t$1 Attached'
17        end
18    end
19    popd >/dev/null
20end
21
22function __fish_complete_screen_general_list -d "Get the socket list"
23    set -l escaped (string escape --style=regex $argv)
24    screen -list | string match -r '^\t.*\('$escaped'\)\s*$' | string replace -r '\t(.*)\s+(\(.*\))?\s*\((.*)\)' '$1\t$3'
25end
26
27function __fish_complete_screen_detached -d "Print a list of detached screen sessions"
28    switch (uname)
29        case Darwin
30            __fish_complete_screen_general_list_mac Detached
31        case '*'
32            __fish_complete_screen_general_list Detached
33    end
34end
35
36function __fish_complete_screen_attached -d "Print a list of attached screen sessions"
37    switch (uname)
38        case Darwin
39            __fish_complete_screen_general_list_mac Attached
40        case '*'
41            __fish_complete_screen_general_list Attached
42    end
43end
44
45function __fish_complete_screen -d "Print a list of running screen sessions"
46    string join \n (__fish_complete_screen_attached) (__fish_complete_screen_detached)
47end
48
49# detect socket directory for mac users
50__fish_detect_screen_socket_dir
51
52complete -c screen -s a -d 'Include all capabilitys'
53complete -c screen -s A -d 'Adapt window size'
54complete -c screen -s c -r -d 'Specify init file'
55complete -c screen -o d -d 'Detach screen' -a '(__fish_complete_screen)' -x
56complete -c screen -o D -d 'Detach screen' -a '(__fish_complete_screen)' -x
57complete -c screen -o r -d 'Reattach session' -a '(__fish_complete_screen)' -x
58complete -c screen -o R -d 'Reattach/create session' -a '(__fish_complete_screen)' -x
59complete -c screen -o RR -d 'Reattach/create any session' -a '(__fish_complete_screen)' -x
60complete -c screen -s e -x -d 'Escape character'
61complete -c screen -s f -d 'Flow control on'
62complete -c screen -o fn -d 'Flow control off'
63complete -c screen -o fa -d 'Flow control automatic'
64complete -c screen -o h -x -d 'History length'
65complete -c screen -s i -d 'Interrupt display on C-c'
66complete -c screen -s l -d 'Login on'
67complete -c screen -o ln -d 'Login off'
68complete -c screen -o ls -d 'List sessions'
69complete -c screen -o list -d 'List sessions'
70complete -c screen -s L -d 'Log on'
71complete -c screen -s m -d 'Ignore $STY'
72complete -c screen -s O -d 'Optimal output'
73complete -c screen -s p -d 'Preselect window'
74complete -c screen -s q -d 'Quiet mode'
75complete -c screen -o s -r -d 'Set shell'
76complete -c screen -o S -x -d 'Session name'
77complete -c screen -o t -x -d 'Session title'
78complete -c screen -o T -x -d 'Value to use for $TERM (default "screen")'
79complete -c screen -s U -d 'UTF-8 mode'
80complete -c screen -s v -d 'Display version and exit'
81complete -c screen -o wipe -d 'Wipe dead sessions'
82complete -c screen -o x -d 'Multi attach' -a '(__fish_complete_screen_attached)' -x
83complete -c screen -o X -r -d 'Send command'