fork/fish-shell

git clone https://git.julia.blue/fork/fish-shell

Johannes AltmanningerPrepare to not localize private function descriptionsd835c5252

master
2.5 KiB72 linesraw
1# localization: skip(barely-used)
2
3# This is a helper function for `fish_opt`. It does some basic validation of the arguments.
4function __fish_opt_validate_args --no-scope-shadowing
5    if not set -q _flag_validate && test (count $argv) -ne 0
6        printf (_ "%s: Extra non-option arguments were provided\n") fish_opt >&2
7        return 1
8    else if set -q _flag_validate && test (count $argv) -eq 0
9        printf (_ "%s: The --validate flag requires subsequent arguments\n") fish_opt >&2
10        return 1
11    else if set -q _flag_validate && not set -q _flag_multiple_vals && not set -q _flag_optional_val && not set -q _flag_required_val
12        printf (_ "%s: The --validate flag requires the --required-val, --optional-value, or --multiple-vals flag\n") fish_opt >&2
13        return 1
14    else if set -q _flag_short && test 1 -ne (string length -- $_flag_short)
15        printf (_ "%s: The --short flag must be a single character\n") fish_opt >&2
16        return 1
17    else if not set -q _flag_short && not set -q _flag_long
18        set -S _flag_short >&2
19        printf (_ "%s: Either the --short or --long flag must be provided\n") fish_opt >&2
20        return 1
21    else if set -q _flag_long_only && not set -q _flag_long
22        printf (_ "%s: The --long-only flag requires the --long flag\n") fish_opt >&2
23        return 1
24    end
25
26    return 0
27end
28
29# The `fish_opt` command.
30function fish_opt -d 'Produce an option specification suitable for use with `argparse`.'
31    set -l options h/help 's/short=' 'l/long=' d/delete o/optional-val r/required-val m/multiple-vals long-only v/validate
32    argparse -n fish_opt --stop-nonopt --exclusive=r,o $options -- $argv
33    or return
34
35    if set -q _flag_help
36        __fish_print_help fish_opt
37        return 0
38    end
39
40    __fish_opt_validate_args $argv
41    or return
42
43    if not set -q _flag_short
44        set opt_spec "/$_flag_long"
45    else if not set -q _flag_long
46        set opt_spec $_flag_short
47    else if set -q _flag_long_only
48        set opt_spec "$_flag_short-$_flag_long"
49    else
50        set opt_spec "$_flag_short/$_flag_long"
51    end
52
53    if set -q _flag_multiple_vals && set -q _flag_optional_val
54        set opt_spec "$opt_spec=*"
55    else if set -q _flag_multiple_vals
56        set opt_spec "$opt_spec=+"
57    else if set -q _flag_required_val
58        set opt_spec "$opt_spec="
59    else if set -q _flag_optional_val
60        and set opt_spec "$opt_spec=?"
61    end
62
63    if set -q _flag_delete
64        set opt_spec "$opt_spec&"
65    end
66
67    if set -q _flag_validate
68        set opt_spec "$opt_spec!$argv"
69    end
70
71    echo $opt_spec
72end