fork/helix

git clone https://git.julia.blue/fork/helix

Sebastian ZivotaMake nix flake respect unused grammars (#9326)a0b02106

24.07
4.1 KiB134 linesraw
1{
2  stdenv,
3  lib,
4  runCommandLocal,
5  runCommand,
6  yj,
7  includeGrammarIf ? _: true,
8  grammarOverlays ? [],
9  ...
10}: let
11  # HACK: nix < 2.6 has a bug in the toml parser, so we convert to JSON
12  # before parsing
13  languages-json = runCommandLocal "languages-toml-to-json" {} ''
14    ${yj}/bin/yj -t < ${./languages.toml} > $out
15  '';
16  languagesConfig =
17    if lib.versionAtLeast builtins.nixVersion "2.6.0"
18    then builtins.fromTOML (builtins.readFile ./languages.toml)
19    else builtins.fromJSON (builtins.readFile (builtins.toPath languages-json));
20  isGitGrammar = grammar:
21    builtins.hasAttr "source" grammar
22    && builtins.hasAttr "git" grammar.source
23    && builtins.hasAttr "rev" grammar.source;
24  isGitHubGrammar = grammar: lib.hasPrefix "https://github.com" grammar.source.git;
25  toGitHubFetcher = url: let
26    match = builtins.match "https://github\.com/([^/]*)/([^/]*)/?" url;
27  in {
28    owner = builtins.elemAt match 0;
29    repo = builtins.elemAt match 1;
30  };
31  # If `use-grammars.only` is set, use only those grammars.
32  # If `use-grammars.except` is set, use all other grammars.
33  # Otherwise use all grammars.
34  useGrammar = grammar:
35    if languagesConfig?use-grammars.only then
36      builtins.elem grammar.name languagesConfig.use-grammars.only
37    else if languagesConfig?use-grammars.except then
38      !(builtins.elem grammar.name languagesConfig.use-grammars.except)
39    else true;
40  grammarsToUse = builtins.filter useGrammar languagesConfig.grammar;
41  gitGrammars = builtins.filter isGitGrammar grammarsToUse;
42  buildGrammar = grammar: let
43    gh = toGitHubFetcher grammar.source.git;
44    sourceGit = builtins.fetchTree {
45      type = "git";
46      url = grammar.source.git;
47      rev = grammar.source.rev;
48      ref = grammar.source.ref or "HEAD";
49      shallow = true;
50    };
51    sourceGitHub = builtins.fetchTree {
52      type = "github";
53      owner = gh.owner;
54      repo = gh.repo;
55      inherit (grammar.source) rev;
56    };
57    source =
58      if isGitHubGrammar grammar
59      then sourceGitHub
60      else sourceGit;
61  in
62    stdenv.mkDerivation {
63      # see https://github.com/NixOS/nixpkgs/blob/fbdd1a7c0bc29af5325e0d7dd70e804a972eb465/pkgs/development/tools/parsing/tree-sitter/grammar.nix
64
65      pname = "helix-tree-sitter-${grammar.name}";
66      version = grammar.source.rev;
67
68      src = source;
69      sourceRoot = if builtins.hasAttr "subpath" grammar.source then
70        "source/${grammar.source.subpath}"
71      else
72        "source";
73
74      dontConfigure = true;
75
76      FLAGS = [
77        "-Isrc"
78        "-g"
79        "-O3"
80        "-fPIC"
81        "-fno-exceptions"
82        "-Wl,-z,relro,-z,now"
83      ];
84
85      NAME = grammar.name;
86
87      buildPhase = ''
88        runHook preBuild
89
90        if [[ -e src/scanner.cc ]]; then
91          $CXX -c src/scanner.cc -o scanner.o $FLAGS
92        elif [[ -e src/scanner.c ]]; then
93          $CC -c src/scanner.c -o scanner.o $FLAGS
94        fi
95
96        $CC -c src/parser.c -o parser.o $FLAGS
97        $CXX -shared -o $NAME.so *.o
98
99        ls -al
100
101        runHook postBuild
102      '';
103
104      installPhase = ''
105        runHook preInstall
106        mkdir $out
107        mv $NAME.so $out/
108        runHook postInstall
109      '';
110
111      # Strip failed on darwin: strip: error: symbols referenced by indirect symbol table entries that can't be stripped
112      fixupPhase = lib.optionalString stdenv.isLinux ''
113        runHook preFixup
114        $STRIP $out/$NAME.so
115        runHook postFixup
116      '';
117    };
118  grammarsToBuild = builtins.filter includeGrammarIf gitGrammars;
119  builtGrammars = builtins.map (grammar: {
120    inherit (grammar) name;
121    value = buildGrammar grammar;
122  }) grammarsToBuild;
123  extensibleGrammars =
124    lib.makeExtensible (self: builtins.listToAttrs builtGrammars);
125  overlayedGrammars = lib.pipe extensibleGrammars
126    (builtins.map (overlay: grammar: grammar.extend overlay) grammarOverlays);
127  grammarLinks = lib.mapAttrsToList
128    (name: artifact: "ln -s ${artifact}/${name}.so $out/${name}.so")
129    (lib.filterAttrs (n: v: lib.isDerivation v) overlayedGrammars);
130in
131  runCommand "consolidated-helix-grammars" {} ''
132    mkdir -p $out
133    ${builtins.concatStringsSep "\n" grammarLinks}
134  ''