fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Gerg-Lflake: fix nixpkgs `config`b2a2133c

master
4.0 KiB126 linesraw
1{
2  description = "Home Manager for Nix";
3
4  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
5
6  outputs = { self, nixpkgs, ... }:
7    {
8      nixosModules = rec {
9        home-manager = import ./nixos;
10        default = home-manager;
11      };
12      # deprecated in Nix 2.8
13      nixosModule = self.nixosModules.default;
14
15      darwinModules = rec {
16        home-manager = import ./nix-darwin;
17        default = home-manager;
18      };
19      # unofficial; deprecated in Nix 2.8
20      darwinModule = self.darwinModules.default;
21
22      templates = {
23        standalone = {
24          path = ./templates/standalone;
25          description = "Standalone setup";
26        };
27        nixos = {
28          path = ./templates/nixos;
29          description = "Home Manager as a NixOS module,";
30        };
31        nix-darwin = {
32          path = ./templates/nix-darwin;
33          description = "Home Manager as a nix-darwin module,";
34        };
35      };
36
37      defaultTemplate = self.templates.standalone;
38
39      lib = {
40        hm = (import ./modules/lib/stdlib-extended.nix nixpkgs.lib).hm;
41        homeManagerConfiguration = { modules ? [ ], pkgs, lib ? pkgs.lib
42          , extraSpecialArgs ? { }, check ? true
43            # Deprecated:
44          , configuration ? null, extraModules ? null, stateVersion ? null
45          , username ? null, homeDirectory ? null, system ? null }@args:
46          let
47            msgForRemovedArg = ''
48              The 'homeManagerConfiguration' arguments
49
50                - 'configuration',
51                - 'username',
52                - 'homeDirectory'
53                - 'stateVersion',
54                - 'extraModules', and
55                - 'system'
56
57              have been removed. Instead use the arguments 'pkgs' and
58              'modules'. See the 22.11 release notes for more: https://nix-community.github.io/home-manager/release-notes.html#sec-release-22.11-highlights
59            '';
60
61            throwForRemovedArgs = v:
62              let
63                used = builtins.filter (n: (args.${n} or null) != null) [
64                  "configuration"
65                  "username"
66                  "homeDirectory"
67                  "stateVersion"
68                  "extraModules"
69                  "system"
70                ];
71                msg = msgForRemovedArg + ''
72
73
74                  Deprecated args passed: ''
75                  + builtins.concatStringsSep " " used;
76              in lib.throwIf (used != [ ]) msg v;
77
78          in throwForRemovedArgs (import ./modules {
79            inherit pkgs lib check extraSpecialArgs;
80            configuration = { ... }: {
81              imports = modules
82                ++ [{ programs.home-manager.path = toString ./.; }];
83              nixpkgs = {
84                config = nixpkgs.lib.mkDefault pkgs.config;
85                inherit (pkgs) overlays;
86              };
87            };
88          });
89      };
90    } // (let
91      forAllSystems = nixpkgs.lib.genAttrs nixpkgs.lib.systems.flakeExposed;
92    in {
93      devShells = forAllSystems (system:
94        let
95          pkgs = nixpkgs.legacyPackages.${system};
96          tests = import ./tests { inherit pkgs; };
97        in tests.run);
98
99      formatter = forAllSystems (system:
100        let pkgs = nixpkgs.legacyPackages.${system};
101        in pkgs.linkFarm "format" [{
102          name = "bin/format";
103          path = ./format;
104        }]);
105
106      packages = forAllSystems (system:
107        let
108          pkgs = nixpkgs.legacyPackages.${system};
109          releaseInfo = nixpkgs.lib.importJSON ./release.json;
110          docs = import ./docs {
111            inherit pkgs;
112            inherit (releaseInfo) release isReleaseBranch;
113          };
114          hmPkg = pkgs.callPackage ./home-manager { path = toString ./.; };
115        in {
116          default = hmPkg;
117          home-manager = hmPkg;
118
119          docs-html = docs.manual.html;
120          docs-json = docs.options.json;
121          docs-manpages = docs.manPages;
122        });
123
124      defaultPackage = forAllSystems (system: self.packages.${system}.default);
125    });
126}