fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.4 KiB59 linesraw
1{ config, pkgs, lib, generators, ... }:
2with lib;
3let
4  cfg = config.i18n.inputMethod.kime;
5  yamlFormat = pkgs.formats.yaml { };
6in {
7  options = {
8    i18n.inputMethod.kime = {
9      config = mkOption {
10        type = yamlFormat.type;
11        default = { };
12        example = literalExpression ''
13          {
14            daemon = {
15              modules = ["Xim" "Indicator"];
16            };
17
18            indicator = {
19              icon_color = "White";
20            };
21
22            engine = {
23              hangul = {
24                layout = "dubeolsik";
25              };
26            };
27          }
28        '';
29        description = ''
30          kime configuration. Refer to
31          <https://github.com/Riey/kime/blob/develop/docs/CONFIGURATION.md>
32          for details on supported values.
33        '';
34      };
35    };
36  };
37
38  config = mkIf (config.i18n.inputMethod.enabled == "kime") {
39    i18n.inputMethod.package = pkgs.kime;
40
41    home.sessionVariables = {
42      GTK_IM_MODULE = "kime";
43      QT_IM_MODULE = "kime";
44      XMODIFIERS = "@im=kime";
45    };
46
47    xdg.configFile."kime/config.yaml".text =
48      replaceStrings [ "\\\\" ] [ "\\" ] (builtins.toJSON cfg.config);
49
50    systemd.user.services.kime-daemon = {
51      Unit = {
52        Description = "Kime input method editor";
53        PartOf = [ "graphical-session.target" ];
54      };
55      Service.ExecStart = "${pkgs.kime}/bin/kime";
56      Install.WantedBy = [ "graphical-session.target" ];
57    };
58  };
59}