fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Thiago Kenji Okadanixpkgs-disabled: add module223a4a17

master
1.9 KiB73 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.nixpkgs;
8
9  # Copied from nixpkgs.nix.
10  isConfig = x: builtins.isAttrs x || builtins.isFunction x;
11
12  # Copied from nixpkgs.nix.
13  optCall = f: x: if builtins.isFunction f then f x else f;
14
15  # Copied from nixpkgs.nix.
16  mergeConfig = lhs_: rhs_:
17    let
18      lhs = optCall lhs_ { inherit pkgs; };
19      rhs = optCall rhs_ { inherit pkgs; };
20    in lhs // rhs // optionalAttrs (lhs ? packageOverrides) {
21      packageOverrides = pkgs:
22        optCall lhs.packageOverrides pkgs
23        // optCall (attrByPath [ "packageOverrides" ] ({ }) rhs) pkgs;
24    } // optionalAttrs (lhs ? perlPackageOverrides) {
25      perlPackageOverrides = pkgs:
26        optCall lhs.perlPackageOverrides pkgs
27        // optCall (attrByPath [ "perlPackageOverrides" ] ({ }) rhs) pkgs;
28    };
29
30  # Copied from nixpkgs.nix.
31  configType = mkOptionType {
32    name = "nixpkgs-config";
33    description = "nixpkgs config";
34    check = x:
35      let traceXIfNot = c: if c x then true else lib.traceSeqN 1 x false;
36      in traceXIfNot isConfig;
37    merge = args: fold (def: mergeConfig def.value) { };
38  };
39
40  # Copied from nixpkgs.nix.
41  overlayType = mkOptionType {
42    name = "nixpkgs-overlay";
43    description = "nixpkgs overlay";
44    check = builtins.isFunction;
45    merge = lib.mergeOneOption;
46  };
47
48in {
49  meta.maintainers = with maintainers; [ thiagokokada ];
50
51  options.nixpkgs = {
52    config = mkOption {
53      default = null;
54      type = types.nullOr configType;
55      visible = false;
56    };
57
58    overlays = mkOption {
59      default = null;
60      type = types.nullOr (types.listOf overlayType);
61      visible = false;
62    };
63  };
64
65  config = {
66    assertions = [{
67      assertion = cfg.config == null || cfg.overlays == null;
68      message = ''
69        `nixpkgs` options are disabled when `home-manager.useGlobalPkgs` is enabled.
70      '';
71    }];
72  };
73}