fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
3.0 KiB110 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.programs.beets;
8
9  yamlFormat = pkgs.formats.yaml { };
10
11in {
12  meta.maintainers = with maintainers; [ rycee Scrumplex ];
13
14  options = {
15    programs.beets = {
16      enable = mkOption {
17        type = types.bool;
18        default = if versionAtLeast config.home.stateVersion "19.03" then
19          false
20        else
21          cfg.settings != { };
22        defaultText = "false";
23        description = ''
24          Whether to enable the beets music library manager. This
25          defaults to `false` for state
26          version ≥ 19.03. For earlier versions beets is enabled if
27          {option}`programs.beets.settings` is non-empty.
28        '';
29      };
30
31      package = mkOption {
32        type = types.package;
33        default = pkgs.beets;
34        defaultText = literalExpression "pkgs.beets";
35        example =
36          literalExpression "(pkgs.beets.override { enableCheck = true; })";
37        description = ''
38          The `beets` package to use.
39          Can be used to specify extensions.
40        '';
41      };
42
43      settings = mkOption {
44        type = yamlFormat.type;
45        default = { };
46        description = ''
47          Configuration written to
48          {file}`$XDG_CONFIG_HOME/beets/config.yaml`
49        '';
50      };
51
52      mpdIntegration = {
53        enableStats = mkEnableOption "mpdstats plugin and service";
54
55        enableUpdate = mkEnableOption "mpdupdate plugin";
56
57        host = mkOption {
58          type = types.str;
59          default = "localhost";
60          example = "10.0.0.42";
61          description = "The host that mpdstats will connect to.";
62        };
63
64        port = mkOption {
65          type = types.port;
66          default = config.services.mpd.network.port;
67          defaultText = literalExpression "config.services.mpd.network.port";
68          example = 6601;
69          description = "The port that mpdstats will connect to.";
70        };
71      };
72    };
73  };
74
75  config = mkMerge [
76    (mkIf cfg.enable {
77      home.packages = [ cfg.package ];
78
79      xdg.configFile."beets/config.yaml".source =
80        yamlFormat.generate "beets-config" cfg.settings;
81    })
82
83    (mkIf (cfg.mpdIntegration.enableStats || cfg.mpdIntegration.enableUpdate) {
84      programs.beets.settings.mpd = {
85        host = cfg.mpdIntegration.host;
86        port = cfg.mpdIntegration.port;
87      };
88    })
89
90    (mkIf cfg.mpdIntegration.enableStats {
91      programs.beets.settings.plugins = [ "mpdstats" ];
92    })
93
94    (mkIf cfg.mpdIntegration.enableUpdate {
95      programs.beets.settings.plugins = [ "mpdupdate" ];
96    })
97
98    (mkIf (cfg.enable && cfg.mpdIntegration.enableStats) {
99      systemd.user.services."beets-mpdstats" = {
100        Unit = {
101          Description = "Beets MPDStats daemon";
102          After = optional config.services.mpd.enable "mpd.service";
103          Requires = optional config.services.mpd.enable "mpd.service";
104        };
105        Service.ExecStart = "${cfg.package}/bin/beet mpdstats";
106        Install.WantedBy = [ "default.target" ];
107      };
108    })
109  ];
110}