fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Harasexa: add aliases to nushell4c0bcf5d

master
1.7 KiB74 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5{
6  imports = let
7    mkRenamed = opt:
8      mkRenamedOptionModule [ "programs" "exa" opt ] [ "programs" "eza" opt ];
9  in map mkRenamed [ "enable" "enableAliases" "extraOptions" "icons" "git" ];
10
11  meta.maintainers = [ maintainers.cafkafk ];
12
13  options.programs.eza = {
14    enable = mkEnableOption "eza, a modern replacement for {command}`ls`";
15
16    enableAliases = mkEnableOption "recommended eza aliases (ls, ll…)";
17
18    extraOptions = mkOption {
19      type = types.listOf types.str;
20      default = [ ];
21      example = [ "--group-directories-first" "--header" ];
22      description = ''
23        Extra command line options passed to eza.
24      '';
25    };
26
27    icons = mkOption {
28      type = types.bool;
29      default = false;
30      description = ''
31        Display icons next to file names ({option}`--icons` argument).
32      '';
33    };
34
35    git = mkOption {
36      type = types.bool;
37      default = false;
38      description = ''
39        List each file's Git status if tracked or ignored ({option}`--git` argument).
40      '';
41    };
42
43    package = mkPackageOption pkgs "eza" { };
44  };
45
46  config = let
47    cfg = config.programs.eza;
48
49    args = escapeShellArgs (optional cfg.icons "--icons"
50      ++ optional cfg.git "--git" ++ cfg.extraOptions);
51
52    aliases = {
53      eza = "eza ${args}";
54    } // optionalAttrs cfg.enableAliases {
55      ls = "eza";
56      ll = "eza -l";
57      la = "eza -a";
58      lt = "eza --tree";
59      lla = "eza -la";
60    };
61  in mkIf cfg.enable {
62    home.packages = [ cfg.package ];
63
64    programs.bash.shellAliases = aliases;
65
66    programs.zsh.shellAliases = aliases;
67
68    programs.fish.shellAliases = aliases;
69
70    programs.ion.shellAliases = aliases;
71
72    programs.nushell.shellAliases = aliases;
73  };
74}