fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.9 KiB80 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.programs.foot;
8  iniFormat = pkgs.formats.ini { };
9
10in {
11  meta.maintainers = with lib.maintainers; [ plabadens ];
12
13  options.programs.foot = {
14    enable = mkEnableOption "Foot terminal";
15
16    package = mkOption {
17      type = types.package;
18      default = pkgs.foot;
19      defaultText = literalExpression "pkgs.foot";
20      description = "The foot package to install";
21    };
22
23    server.enable = mkEnableOption "Foot terminal server";
24
25    settings = mkOption {
26      type = iniFormat.type;
27      default = { };
28      description = ''
29        Configuration written to
30        {file}`$XDG_CONFIG_HOME/foot/foot.ini`. See <https://codeberg.org/dnkl/foot/src/branch/master/foot.ini>
31        for a list of available options.
32      '';
33      example = literalExpression ''
34        {
35          main = {
36            term = "xterm-256color";
37
38            font = "Fira Code:size=11";
39            dpi-aware = "yes";
40          };
41
42          mouse = {
43            hide-when-typing = "yes";
44          };
45        }
46      '';
47    };
48  };
49
50  config = mkIf cfg.enable {
51    assertions =
52      [ (hm.assertions.assertPlatform "programs.foot" pkgs platforms.linux) ];
53
54    home.packages = [ cfg.package ];
55
56    xdg.configFile."foot/foot.ini" = mkIf (cfg.settings != { }) {
57      source = iniFormat.generate "foot.ini" cfg.settings;
58    };
59
60    systemd.user.services = mkIf cfg.server.enable {
61      foot = {
62        Unit = {
63          Description =
64            "Fast, lightweight and minimalistic Wayland terminal emulator.";
65          Documentation = "man:foot(1)";
66          PartOf = [ "graphical-session.target" ];
67          After = [ "graphical-session.target" ];
68        };
69
70        Service = {
71          ExecStart = "${cfg.package}/bin/foot --server";
72          Restart = "on-failure";
73          OOMPolicy = "continue";
74        };
75
76        Install = { WantedBy = [ "graphical-session.target" ]; };
77      };
78    };
79  };
80}