fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.6 KiB69 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.programs.ledger;
8
9  cfgText = generators.toKeyValue {
10    mkKeyValue = key: value:
11      if isBool value then
12        optionalString value "--${key}"
13      else
14        "--${key} ${toString value}";
15    listsAsDuplicateKeys = true;
16  } cfg.settings;
17
18in {
19  meta.maintainers = [ ];
20
21  options.programs.ledger = {
22    enable = mkEnableOption "ledger, a double-entry accounting system";
23
24    package = mkPackageOption pkgs "ledger" { };
25
26    settings = mkOption {
27      type = with types; attrsOf (oneOf [ bool int str (listOf str) ]);
28      default = { };
29      example = {
30        sort = "date";
31        date-format = "%Y-%m-%d";
32        strict = true;
33        file = [
34          "~/finances/journal.ledger"
35          "~/finances/assets.ledger"
36          "~/finances/income.ledger"
37        ];
38      };
39      description = ''
40        Configuration written to {file}`$XDG_CONFIG_HOME/ledger/ledgerrc`.
41        See <https://www.ledger-cli.org/3.0/doc/ledger3.html#Detailed-Option-Description>
42        for explanation about possible values.
43      '';
44    };
45
46    extraConfig = mkOption {
47      type = types.lines;
48      default = "";
49      example = literalExpression ''
50        --sort date
51        --effective
52        --date-format %Y-%m-%d
53      '';
54      description = ''
55        Extra configuration to add to
56        {file}`$XDG_CONFIG_HOME/ledger/ledgerrc`.
57      '';
58    };
59  };
60
61  config = mkIf cfg.enable {
62    home.packages = [ cfg.package ];
63
64    xdg.configFile."ledger/ledgerrc" =
65      mkIf (cfg.settings != { } || cfg.extraConfig != "") {
66        text = cfgText + cfg.extraConfig;
67      };
68  };
69}