fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.4 KiB59 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.programs.librewolf;
8
9  mkOverridesFile = prefs: ''
10    // Generated by Home Manager.
11
12    ${concatStrings (mapAttrsToList (name: value: ''
13      defaultPref("${name}", ${builtins.toJSON value});
14    '') prefs)}
15  '';
16
17in {
18  meta.maintainers = [ maintainers.onny ];
19
20  options.programs.librewolf = {
21    enable =
22      mkEnableOption "Librewolf browser, a privacy enhanced Firefox fork";
23
24    package = mkOption {
25      type = types.package;
26      default = pkgs.librewolf;
27      defaultText = literalExpression "pkgs.librewolf";
28      description = "The LibreWolf package to use.";
29    };
30
31    settings = mkOption {
32      type = with types; attrsOf (either bool (either int str));
33      default = { };
34      example = literalExpression ''
35        {
36          "webgl.disabled" = false;
37          "privacy.resistFingerprinting" = false;
38        }
39      '';
40      description = ''
41        Attribute set of LibreWolf settings and overrides. Refer to
42        <https://librewolf.net/docs/settings/>
43        for details on supported values.
44      '';
45    };
46  };
47
48  config = mkIf cfg.enable {
49    assertions = [
50      (lib.hm.assertions.assertPlatform "programs.librewolf" pkgs
51        lib.platforms.linux)
52    ];
53
54    home.packages = [ cfg.package ];
55
56    home.file.".librewolf/librewolf.overrides.cfg".text =
57      mkOverridesFile cfg.settings;
58  };
59}