fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
2.0 KiB86 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4let
5
6  cfg = config.programs.navi;
7
8  yamlFormat = pkgs.formats.yaml { };
9
10  configDir = if pkgs.stdenv.isDarwin then
11    "Library/Application Support"
12  else
13    config.xdg.configHome;
14
15in {
16  meta.maintainers = [ ];
17
18  options.programs.navi = {
19    enable = mkEnableOption "Navi";
20
21    package = mkOption {
22      type = types.package;
23      default = pkgs.navi;
24      defaultText = literalExpression "pkgs.navi";
25      description = "The package to use for the navi binary.";
26    };
27
28    settings = mkOption {
29      type = yamlFormat.type;
30      default = { };
31      example = literalExpression ''
32        {
33          cheats = {
34            paths = [
35              "~/cheats/"
36            ];
37          };
38        }
39      '';
40      description = ''
41        Configuration written to
42        {file}`$XDG_CONFIG_HOME/navi/config.yaml` on Linux or
43        {file}`$HOME/Library/Application Support/navi/config.yaml`
44        on Darwin. See
45        <https://github.com/denisidoro/navi/blob/master/docs/config_file.md>
46        for more information.
47      '';
48    };
49
50    enableBashIntegration = mkEnableOption "Bash integration" // {
51      default = true;
52    };
53
54    enableZshIntegration = mkEnableOption "Zsh integration" // {
55      default = true;
56    };
57
58    enableFishIntegration = mkEnableOption "Fish integration" // {
59      default = true;
60    };
61  };
62
63  config = mkIf cfg.enable {
64    home.packages = [ cfg.package ];
65
66    programs.bash.initExtra = mkIf cfg.enableBashIntegration ''
67      if [[ :$SHELLOPTS: =~ :(vi|emacs): ]]; then
68        eval "$(${cfg.package}/bin/navi widget bash)"
69      fi
70    '';
71
72    programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
73      if [[ $options[zle] = on ]]; then
74        eval "$(${cfg.package}/bin/navi widget zsh)"
75      fi
76    '';
77
78    programs.fish.shellInit = mkIf cfg.enableFishIntegration ''
79      ${cfg.package}/bin/navi widget fish | source
80    '';
81
82    home.file."${configDir}/navi/config.yaml" = mkIf (cfg.settings != { }) {
83      source = yamlFormat.generate "navi-config" cfg.settings;
84    };
85  };
86}