fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
2.1 KiB95 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.programs.ne;
8
9  autoPrefFiles = let
10    autoprefs = cfg.automaticPreferences
11      // optionalAttrs (cfg.defaultPreferences != "") {
12        ".default" = cfg.defaultPreferences;
13      };
14
15    gen = fileExtension: configText:
16      nameValuePair ".ne/${fileExtension}#ap" {
17        text = configText;
18      }; # Generates [path].text format expected by home.file.
19  in mapAttrs' gen autoprefs;
20
21in {
22  meta.maintainers = [ hm.maintainers.cwyc ];
23
24  options.programs.ne = {
25    enable = mkEnableOption "ne";
26
27    keybindings = mkOption {
28      type = types.lines;
29      default = "";
30      example = ''
31        KEY 7f BS
32        SEQ "\x1b[1;5D" 7f
33      '';
34      description = ''
35        Keybinding file for ne.
36      '';
37    };
38
39    defaultPreferences = mkOption {
40      type = types.lines;
41      default = "";
42      description = ''
43        Default preferences for ne.
44
45        Equivalent to `programs.ne.automaticPreferences.".default"`.
46      '';
47    };
48
49    automaticPreferences = mkOption {
50      type = types.attrsOf types.lines;
51      default = { };
52      example = literalExpression ''
53        {
54          nix = '''
55            TAB 0
56            TS 2
57          ''';
58          js = '''
59            TS 4
60          ''';
61        }
62      '';
63      description = ''
64        Automatic preferences files for ne.
65      '';
66    };
67
68    menus = mkOption {
69      type = types.lines;
70      default = "";
71      description = "Menu configuration file for ne.";
72    };
73
74    virtualExtensions = mkOption {
75      type = types.lines;
76      default = "";
77      example = ''
78        sh   1  ^#!\s*/.*\b(bash|sh|ksh|zsh)\s*
79        csh  1  ^#!\s*/.*\b(csh|tcsh)\s*
80      '';
81      description = "Virtual extensions configuration file for ne.";
82    };
83  };
84
85  config = mkIf cfg.enable {
86    home.packages = [ pkgs.ne ];
87
88    home.file = {
89      ".ne/.keys" = mkIf (cfg.keybindings != "") { text = cfg.keybindings; };
90      ".ne/.extensions" =
91        mkIf (cfg.virtualExtensions != "") { text = cfg.virtualExtensions; };
92      ".ne/.menus" = mkIf (cfg.menus != "") { text = cfg.menus; };
93    } // autoPrefFiles;
94  };
95}