fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
2.1 KiB93 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.programs.rbenv;
8
9  pluginModule = types.submodule {
10    options = {
11      src = mkOption {
12        type = types.path;
13        description = ''
14          Path to the plugin folder.
15        '';
16      };
17      name = mkOption {
18        type = types.str;
19        description = ''
20          Name of the plugin.
21        '';
22      };
23    };
24  };
25
26in {
27  meta.maintainers = [ ];
28
29  options.programs.rbenv = {
30    enable = mkEnableOption "rbenv";
31
32    package = mkPackageOption pkgs "rbenv" { };
33
34    plugins = mkOption {
35      type = types.listOf pluginModule;
36      default = [ ];
37      example = literalExpression ''
38        [
39          {
40            name = "ruby-build";
41            src = pkgs.fetchFromGitHub {
42              owner = "rbenv";
43              repo = "ruby-build";
44              rev = "v20221225";
45              hash = "sha256-Kuq0Z1kh2mvq7rHEgwVG9XwzR5ZUtU/h8SQ7W4/mBU0=";
46            };
47          }
48        ]
49      '';
50      description = ''
51        rbenv plugins to install in {file}`$HOME/.rbenv/plugins/`.
52
53        See <https://github.com/rbenv/rbenv/wiki/Plugins>
54        for the full list of plugins.
55      '';
56    };
57
58    enableBashIntegration = mkEnableOption "Bash integration" // {
59      default = true;
60    };
61
62    enableZshIntegration = mkEnableOption "Zsh integration" // {
63      default = true;
64    };
65
66    enableFishIntegration = mkEnableOption "Fish integration" // {
67      default = true;
68    };
69  };
70
71  config = mkIf cfg.enable {
72    home.packages = [ cfg.package ];
73
74    home.file.".rbenv/plugins" = mkIf (cfg.plugins != [ ]) {
75      source = pkgs.linkFarm "rbenv-plugins" (builtins.map (p: {
76        name = p.name;
77        path = p.src;
78      }) cfg.plugins);
79    };
80
81    programs.bash.initExtra = mkIf cfg.enableBashIntegration ''
82      eval "$(${cfg.package}/bin/rbenv init - bash)"
83    '';
84
85    programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
86      eval "$(${cfg.package}/bin/rbenv init - zsh)"
87    '';
88
89    programs.fish.shellInit = mkIf cfg.enableFishIntegration ''
90      ${cfg.package}/bin/rbenv init - fish | source
91    '';
92  };
93}