fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.2 KiB53 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4let
5  cfg = config.programs.tealdeer;
6
7  tomlFormat = pkgs.formats.toml { };
8
9  configDir = if pkgs.stdenv.isDarwin then
10    "Library/Application Support"
11  else
12    config.xdg.configHome;
13
14in {
15  meta.maintainers = [ ];
16
17  options.programs.tealdeer = {
18    enable = mkEnableOption "Tealdeer";
19
20    settings = mkOption {
21      type = tomlFormat.type;
22      default = { };
23      defaultText = literalExpression "{ }";
24      example = literalExpression ''
25        {
26          display = {
27            compact = false;
28            use_pager = true;
29          };
30          updates = {
31            auto_update = false;
32          };
33        };
34      '';
35      description = ''
36        Configuration written to
37        {file}`$XDG_CONFIG_HOME/tealdeer/config.toml` on Linux or
38        {file}`$HOME/Library/Application Support/tealdeer/config.toml`
39        on Darwin. See
40        <https://dbrgn.github.io/tealdeer/config.html>
41        for more information.
42      '';
43    };
44  };
45
46  config = mkIf cfg.enable {
47    home.packages = [ pkgs.tealdeer ];
48
49    home.file."${configDir}/tealdeer/config.toml" = mkIf (cfg.settings != { }) {
50      source = tomlFormat.generate "tealdeer-config" cfg.settings;
51    };
52  };
53}