fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.7 KiB72 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.programs.terminator;
8
9  toValue = val:
10    if val == null then
11      "None"
12    else if val == true then
13      "True"
14    else if val == false then
15      "False"
16    else
17      ''"${toString val}"'';
18
19  toConfigObject = let
20    toKey = depth: key:
21      if depth == 0 then key else toKey (depth - 1) "[${key}]";
22    toConfigObjectLevel = depth: obj:
23      flatten (mapAttrsToList (key: val:
24        if isAttrs val then
25          [ (toKey depth key) ] ++ toConfigObjectLevel (depth + 1) val
26        else
27          [ "${key} = ${toValue val}" ]) obj);
28  in obj: concatStringsSep "\n" (toConfigObjectLevel 1 obj);
29
30in {
31  meta.maintainers = [ maintainers.chisui ];
32
33  options.programs.terminator = {
34    enable = mkEnableOption "terminator, a tiling terminal emulator";
35
36    package = mkOption {
37      type = types.package;
38      default = pkgs.terminator;
39      example = literalExpression "pkgs.terminator";
40      description = "terminator package to install.";
41    };
42
43    config = mkOption {
44      default = { };
45      description = ''
46        configuration for terminator.
47
48        For a list of all possible options refer to the
49        {manpage}`terminator_config(5)`
50        man page.
51      '';
52      type = types.attrsOf types.anything;
53      example = literalExpression ''
54        {
55          global_config.borderless = true;
56          profiles.default.background_color = "#002b36";
57        }
58      '';
59    };
60  };
61
62  config = mkIf cfg.enable {
63    assertions = [
64      (hm.assertions.assertPlatform "programs.terminator" pkgs platforms.linux)
65    ];
66
67    home.packages = [ cfg.package ];
68
69    xdg.configFile."terminator/config" =
70      mkIf (cfg.config != { }) { text = toConfigObject cfg.config; };
71  };
72}