fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.3 KiB60 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.programs.topgrade;
8
9  tomlFormat = pkgs.formats.toml { };
10
11in {
12
13  meta.maintainers = [ hm.maintainers.msfjarvis ];
14
15  options.programs.topgrade = {
16    enable = mkEnableOption "topgrade";
17
18    package = mkOption {
19      type = types.package;
20      default = pkgs.topgrade;
21      defaultText = literalExpression "pkgs.topgrade";
22      description = "The package to use for the topgrade binary.";
23    };
24
25    settings = mkOption {
26      type = tomlFormat.type;
27      default = { };
28      defaultText = literalExpression "{ }";
29      example = literalExpression ''
30        {
31          assume_yes = true;
32          disable = [
33            "flutter"
34            "node"
35          ];
36          set_title = false;
37          cleanup = true;
38          commands = {
39            "Run garbage collection on Nix store" = "nix-collect-garbage";
40          };
41        }
42      '';
43      description = ''
44        Configuration written to
45        {file}`$XDG_CONFIG_HOME/topgrade.toml`.
46
47        See <https://github.com/r-darwish/topgrade/wiki/Step-list> for the full list
48        of options.
49      '';
50    };
51  };
52
53  config = mkIf cfg.enable {
54    home.packages = [ cfg.package ];
55
56    xdg.configFile."topgrade.toml" = mkIf (cfg.settings != { }) {
57      source = tomlFormat.generate "topgrade-config" cfg.settings;
58    };
59  };
60}