fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
2.2 KiB84 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.programs.zellij;
8  yamlFormat = pkgs.formats.yaml { };
9
10in {
11  meta.maintainers = [ hm.maintainers.mainrs ];
12
13  options.programs.zellij = {
14    enable = mkEnableOption "zellij";
15
16    package = mkOption {
17      type = types.package;
18      default = pkgs.zellij;
19      defaultText = literalExpression "pkgs.zellij";
20      description = ''
21        The zellij package to install.
22      '';
23    };
24
25    settings = mkOption {
26      type = yamlFormat.type;
27      default = { };
28      example = literalExpression ''
29        {
30          theme = "custom";
31          themes.custom.fg = "#ffffff";
32        }
33      '';
34      description = ''
35        Configuration written to
36        {file}`$XDG_CONFIG_HOME/zellij/config.yaml`.
37
38        See <https://zellij.dev/documentation> for the full
39        list of options.
40      '';
41    };
42
43    enableBashIntegration = mkEnableOption "Bash integration" // {
44      default = false;
45    };
46
47    enableZshIntegration = mkEnableOption "Zsh integration" // {
48      default = false;
49    };
50
51    enableFishIntegration = mkEnableOption "Fish integration" // {
52      default = false;
53    };
54  };
55
56  config = mkIf cfg.enable {
57    home.packages = [ cfg.package ];
58
59    # Zellij switched from yaml to KDL in version 0.32.0:
60    # https://github.com/zellij-org/zellij/releases/tag/v0.32.0
61    xdg.configFile."zellij/config.yaml" = mkIf
62      (cfg.settings != { } && (versionOlder cfg.package.version "0.32.0")) {
63        source = yamlFormat.generate "zellij.yaml" cfg.settings;
64      };
65
66    xdg.configFile."zellij/config.kdl" = mkIf
67      (cfg.settings != { } && (versionAtLeast cfg.package.version "0.32.0")) {
68        text = lib.hm.generators.toKDL { } cfg.settings;
69      };
70
71    programs.bash.initExtra = mkIf cfg.enableBashIntegration (mkOrder 200 ''
72      eval "$(zellij setup --generate-auto-start bash)"
73    '');
74
75    programs.zsh.initExtra = mkIf cfg.enableZshIntegration (mkOrder 200 ''
76      eval "$(zellij setup --generate-auto-start zsh)"
77    '');
78
79    programs.fish.interactiveShellInit = mkIf cfg.enableFishIntegration
80      (mkOrder 200 ''
81        eval (zellij setup --generate-auto-start fish | string collect)
82      '');
83  };
84}