fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.9 KiB76 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6  cfg = config.services.avizo;
7  settingsFormat = pkgs.formats.ini { };
8in {
9  meta.maintainers = [ hm.maintainers.pltanton ];
10
11  options.services.avizo = {
12    enable = mkEnableOption "avizo, a simple notification daemon";
13
14    settings = mkOption {
15      type = (pkgs.formats.ini { }).type;
16      default = { };
17      example = literalExpression ''
18        {
19          default = {
20            time = 1.0;
21            y-offset = 0.5;
22            fade-in = 0.1;
23            fade-out = 0.2;
24            padding = 10;
25          };
26        }
27      '';
28      description = ''
29        The settings that will be written to the avizo configuration file.
30      '';
31    };
32
33    package = mkOption {
34      type = types.package;
35      default = pkgs.avizo;
36      defaultText = literalExpression "pkgs.avizo";
37      example = literalExpression ''
38        pkgs.avizo.overrideAttrs (final: prev: {
39          patchPhase = "cp ''${./images}/*.png data/images/";
40        })
41      '';
42      description = "The `avizo` package to use.";
43    };
44  };
45
46  config = mkIf cfg.enable {
47    assertions =
48      [ (hm.assertions.assertPlatform "services.avizo" pkgs platforms.linux) ];
49
50    xdg.configFile."avizo/config.ini" = mkIf (cfg.settings != { }) {
51      source = settingsFormat.generate "avizo-config.ini" cfg.settings;
52    };
53
54    home.packages = [ cfg.package ];
55
56    systemd.user = {
57      services.avizo = {
58        Unit = {
59          Description = "Volume/backlight OSD indicator";
60          PartOf = [ "graphical-session.target" ];
61          After = [ "graphical-session.target" ];
62          ConditionEnvironment = "WAYLAND_DISPLAY";
63          Documentation = "man:avizo(1)";
64        };
65
66        Service = {
67          Type = "simple";
68          ExecStart = "${cfg.package}/bin/avizo-service";
69          Restart = "always";
70        };
71
72        Install = { WantedBy = [ "graphical-session.target" ]; };
73      };
74    };
75  };
76}