fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Ilan Joselevichbatsignal: add modulefa980cc9

master
1.2 KiB50 linesraw
1{ config, lib, pkgs, ... }:
2
3let
4
5  cfg = config.services.batsignal;
6
7in {
8  meta.maintainers = with lib.maintainers; [ kranzes ];
9
10  options = {
11    services.batsignal = {
12      enable = lib.mkEnableOption "Batsignal Battery Daemon";
13
14      package = lib.mkPackageOption pkgs "batsignal" { };
15
16      extraArgs = lib.mkOption {
17        type = with lib.types; listOf str;
18        default = [ ];
19        description = ''
20          Extra arguments to be passed to the batsignal executable.
21        '';
22      };
23    };
24  };
25
26  config = lib.mkIf cfg.enable {
27    assertions = [
28      (lib.hm.assertions.assertPlatform "services.batsignal" pkgs
29        lib.platforms.linux)
30    ];
31
32    systemd.user.services.batsignal = {
33      Unit = {
34        Description = "batsignal - battery monitor daemon";
35        After = [ "graphical-session-pre.target" ];
36        PartOf = [ "graphical-session.target" ];
37      };
38
39      Service = {
40        Type = "simple";
41        ExecStart =
42          "${lib.getExe cfg.package} ${lib.escapeShellArgs cfg.extraArgs}";
43        Restart = "on-failure";
44        RestartSec = 1;
45      };
46
47      Install.WantedBy = [ "graphical-session.target" ];
48    };
49  };
50}