fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.3 KiB55 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let cfg = config.services.betterlockscreen;
6
7in {
8  meta.maintainers = with maintainers; [ sebtm ];
9
10  options = {
11    services.betterlockscreen = {
12      enable = mkEnableOption "betterlockscreen, a screen-locker module";
13
14      package = mkOption {
15        type = types.package;
16        default = pkgs.betterlockscreen;
17        defaultText = literalExpression "pkgs.betterlockscreen";
18        description = "Package providing {command}`betterlockscreen`.";
19      };
20
21      arguments = mkOption {
22        type = types.listOf types.str;
23        default = [ ];
24        description =
25          "List of arguments appended to `./betterlockscreen --lock [args]`";
26      };
27
28      inactiveInterval = mkOption {
29        type = types.int;
30        default = 10;
31        description = ''
32          Value used for {option}`services.screen-locker.inactiveInterval`.
33        '';
34      };
35
36    };
37  };
38
39  config = mkIf cfg.enable {
40    assertions = [
41      (lib.hm.assertions.assertPlatform "services.betterlockscreen" pkgs
42        lib.platforms.linux)
43    ];
44
45    home.packages = [ cfg.package ];
46
47    services.screen-locker = {
48      enable = true;
49      inactiveInterval = cfg.inactiveInterval;
50      lockCmd = "${cfg.package}/bin/betterlockscreen --lock ${
51          concatStringsSep " " cfg.arguments
52        }";
53    };
54  };
55}