fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Joseph Ryanclipmenu: set Environment to a list831b4fa3

master
1.4 KiB63 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.services.clipmenu;
8
9in {
10  meta.maintainers = [ maintainers.DamienCassou ];
11
12  options.services.clipmenu = {
13    enable = mkEnableOption "clipmenu, the clipboard management daemon";
14
15    package = mkOption {
16      type = types.package;
17      default = pkgs.clipmenu;
18      defaultText = "pkgs.clipmenu";
19      description = "clipmenu derivation to use.";
20    };
21
22    launcher = mkOption {
23      type = types.nullOr types.str;
24      default = null;
25      example = "rofi";
26      description = ''
27        Launcher command, if not set, {command}`dmenu`
28        will be used by default.
29      '';
30    };
31  };
32
33  config = mkIf cfg.enable {
34    assertions = [
35      (lib.hm.assertions.assertPlatform "services.clipmenu" pkgs
36        lib.platforms.linux)
37    ];
38
39    home.packages = [ cfg.package ];
40
41    home.sessionVariables =
42      mkIf (cfg.launcher != null) { CM_LAUNCHER = cfg.launcher; };
43
44    systemd.user.services.clipmenu = {
45      Unit = {
46        Description = "Clipboard management daemon";
47        After = [ "graphical-session.target" ];
48      };
49
50      Service = {
51        ExecStart = "${cfg.package}/bin/clipmenud";
52        Environment = [
53          "PATH=${
54            makeBinPath
55            (with pkgs; [ coreutils findutils gnugrep gnused systemd ])
56          }"
57        ];
58      };
59
60      Install = { WantedBy = [ "graphical-session.target" ]; };
61    };
62  };
63}