fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
3.8 KiB135 linesraw
1{ pkgs, config, lib, ... }:
2let
3  inherit (lib)
4    mkOption mkEnableOption mkIf maintainers literalExpression types platforms
5    mkRemovedOptionModule versionAtLeast;
6
7  inherit (lib.hm.assertions) assertPlatform;
8
9  cfg = config.services.espanso;
10  espansoVersion = cfg.package.version;
11
12  yaml = pkgs.formats.yaml { };
13in {
14  imports = [
15    (mkRemovedOptionModule [ "services" "espanso" "settings" ]
16      "Use services.espanso.configs and services.espanso.matches instead.")
17  ];
18  meta.maintainers = [
19    maintainers.lucasew
20    maintainers.bobvanderlinden
21    lib.hm.maintainers.liyangau
22  ];
23  options = {
24    services.espanso = {
25      enable = mkEnableOption "Espanso: cross platform text expander in Rust";
26
27      package = mkOption {
28        type = types.package;
29        description = "Which espanso package to use";
30        default = pkgs.espanso;
31        defaultText = literalExpression "pkgs.espanso";
32      };
33
34      configs = mkOption {
35        type = yaml.type;
36        default = { default = { }; };
37        example = literalExpression ''
38          {
39            default = {
40              show_notifications = false;
41            };
42            vscode = {
43              filter_title = "Visual Studio Code$";
44              backend = "Clipboard";
45            };
46          };
47        '';
48        description = ''
49          The Espanso configuration to use. See
50          <https://espanso.org/docs/configuration/basics/>
51          for a description of available options.
52        '';
53      };
54
55      matches = mkOption {
56        type = yaml.type;
57        default = { default.matches = [ ]; };
58        example = literalExpression ''
59          {
60            base = {
61              matches = [
62                {
63                  trigger = ":now";
64                  replace = "It's {{currentdate}} {{currenttime}}";
65                }
66                {
67                  trigger = ":hello";
68                  replace = "line1\nline2";
69                }
70                {
71                  regex = ":hi(?P<person>.*)\\.";
72                  replace = "Hi {{person}}!";
73                }
74              ];
75            };
76            global_vars = {
77              global_vars = [
78                {
79                  name = "currentdate";
80                  type = "date";
81                  params = {format = "%d/%m/%Y";};
82                }
83                {
84                  name = "currenttime";
85                  type = "date";
86                  params = {format = "%R";};
87                }
88              ];
89            };
90          };
91        '';
92        description = ''
93          The Espanso matches to use. See
94          <https://espanso.org/docs/matches/basics/>
95          for a description of available options.
96        '';
97      };
98    };
99  };
100
101  config = mkIf cfg.enable {
102    assertions = [
103      (assertPlatform "services.espanso" pkgs platforms.linux)
104      {
105        assertion = versionAtLeast espansoVersion "2";
106        message = ''
107          The services.espanso module only supports Espanso version 2 or later.
108        '';
109      }
110    ];
111
112    home.packages = [ cfg.package ];
113
114    xdg.configFile = let
115      configFiles = lib.mapAttrs' (name: value: {
116        name = "espanso/config/${name}.yml";
117        value = { source = yaml.generate "${name}.yml" value; };
118      }) cfg.configs;
119      matchesFiles = lib.mapAttrs' (name: value: {
120        name = "espanso/match/${name}.yml";
121        value = { source = yaml.generate "${name}.yml" value; };
122      }) cfg.matches;
123    in configFiles // matchesFiles;
124
125    systemd.user.services.espanso = {
126      Unit = { Description = "Espanso: cross platform text expander in Rust"; };
127      Service = {
128        Type = "exec";
129        ExecStart = "${cfg.package}/bin/espanso daemon";
130        Restart = "on-failure";
131      };
132      Install = { WantedBy = [ "default.target" ]; };
133    };
134  };
135}