fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.8 KiB66 linesraw
1{ config, lib, pkgs, ... }:
2
3let
4
5  cfg = config.services.home-manager.autoUpgrade;
6
7  homeManagerPackage = pkgs.callPackage ../../home-manager {
8    path = config.programs.home-manager.path;
9  };
10
11in {
12  meta.maintainers = [ lib.hm.maintainers.pinage404 ];
13
14  options = {
15    services.home-manager.autoUpgrade = {
16      enable = lib.mkEnableOption ''
17        the Home Manager upgrade service that periodically updates your Nix
18        channels before running `home-manager switch`'';
19
20      frequency = lib.mkOption {
21        type = lib.types.str;
22        example = "weekly";
23        description = ''
24          The interval at which the Home Manager auto upgrade is run.
25          This value is passed to the systemd timer configuration
26          as the `OnCalendar` option.
27          The format is described in
28          {manpage}`systemd.time(7)`.
29        '';
30      };
31    };
32  };
33
34  config = lib.mkIf cfg.enable {
35    assertions = [
36      (lib.hm.assertions.assertPlatform "services.home-manager.autoUpgrade" pkgs
37        lib.platforms.linux)
38    ];
39
40    systemd.user = {
41      timers.home-manager-auto-upgrade = {
42        Unit.Description = "Home Manager upgrade timer";
43
44        Install.WantedBy = [ "timers.target" ];
45
46        Timer = {
47          OnCalendar = cfg.frequency;
48          Unit = "home-manager-auto-upgrade.service";
49          Persistent = true;
50        };
51      };
52
53      services.home-manager-auto-upgrade = {
54        Unit.Description = "Home Manager upgrade";
55
56        Service.ExecStart = toString
57          (pkgs.writeShellScript "home-manager-auto-upgrade" ''
58            echo "Update Nix's channels"
59            ${pkgs.nix}/bin/nix-channel --update
60            echo "Upgrade Home Manager"
61            ${homeManagerPackage}/bin/home-manager switch
62          '');
63      };
64    };
65  };
66}