fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.5 KiB64 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.services.kbfs;
8
9in {
10  options = {
11    services.kbfs = {
12      enable = mkEnableOption "Keybase File System";
13
14      mountPoint = mkOption {
15        type = types.str;
16        default = "keybase";
17        description = ''
18          Mount point for the Keybase filesystem, relative to
19          {env}`HOME`.
20        '';
21      };
22
23      extraFlags = mkOption {
24        type = types.listOf types.str;
25        default = [ ];
26        example = [ "-label kbfs" "-mount-type normal" ];
27        description = ''
28          Additional flags to pass to the Keybase filesystem on launch.
29        '';
30      };
31    };
32  };
33
34  config = mkIf cfg.enable {
35    assertions = [
36      (lib.hm.assertions.assertPlatform "services.kbfs" pkgs
37        lib.platforms.linux)
38    ];
39
40    systemd.user.services.kbfs = {
41      Unit = {
42        Description = "Keybase File System";
43        Requires = [ "keybase.service" ];
44        After = [ "keybase.service" ];
45      };
46
47      Service = let mountPoint = ''"%h/${cfg.mountPoint}"'';
48      in {
49        Environment = "PATH=/run/wrappers/bin KEYBASE_SYSTEMD=1";
50        ExecStartPre = "${pkgs.coreutils}/bin/mkdir -p ${mountPoint}";
51        ExecStart =
52          "${pkgs.kbfs}/bin/kbfsfuse ${toString cfg.extraFlags} ${mountPoint}";
53        ExecStopPost = "/run/wrappers/bin/fusermount -u ${mountPoint}";
54        Restart = "on-failure";
55        PrivateTmp = true;
56      };
57
58      Install.WantedBy = [ "default.target" ];
59    };
60
61    home.packages = [ pkgs.kbfs ];
62    services.keybase.enable = true;
63  };
64}