fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
1.7 KiB63 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6  cfg = config.services.mpd-discord-rpc;
7  tomlFormat = pkgs.formats.toml { };
8  configFile = tomlFormat.generate "config.toml" cfg.settings;
9in {
10  meta.maintainers = [ maintainers.kranzes ];
11
12  options.services.mpd-discord-rpc = {
13    enable = mkEnableOption "the mpd-discord-rpc service";
14
15    settings = mkOption {
16      type = tomlFormat.type;
17      default = { };
18      example = literalExpression ''
19        {
20          hosts = [ "localhost:6600" ];
21          format = {
22            details = "$title";
23            state = "On $album by $artist";
24          };
25        }
26      '';
27      description = ''
28        Configuration included in `config.toml`.
29        For available options see <https://github.com/JakeStanger/mpd-discord-rpc#configuration>
30      '';
31    };
32
33    package = mkOption {
34      type = types.package;
35      default = pkgs.mpd-discord-rpc;
36      defaultText = literalExpression "pkgs.mpd-discord-rpc";
37      description = "mpd-discord-rpc package to use.";
38    };
39  };
40
41  config = mkIf cfg.enable {
42    assertions = [
43      (hm.assertions.assertPlatform "services.mpd-discord-rpc" pkgs
44        platforms.linux)
45    ];
46
47    xdg.configFile."discord-rpc/config.toml".source = configFile;
48
49    systemd.user.services.mpd-discord-rpc = {
50      Unit = {
51        Description = "Discord Rich Presence for MPD";
52        Documentation = "https://github.com/JakeStanger/mpd-discord-rpc";
53        After = [ "graphical-session-pre.target" ];
54        PartOf = [ "graphical-session.target" ];
55      };
56      Service = {
57        ExecStart = "${cfg.package}/bin/mpd-discord-rpc";
58        Restart = "on-failure";
59      };
60      Install.WantedBy = [ "graphical-session.target" ];
61    };
62  };
63}