fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Anton Plotnikovswayosd: add module98282a48

master
1.4 KiB58 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.services.swayosd;
8
9in {
10  meta.maintainers = [ hm.maintainers.pltanton ];
11
12  options.services.swayosd = {
13    enable = mkEnableOption ''
14      swayosd, a GTK based on screen display for keyboard shortcuts like
15      caps-lock and volume'';
16
17    package = mkPackageOption pkgs "swayosd" { };
18
19    maxVolume = mkOption {
20      type = types.nullOr types.ints.unsigned;
21      default = null;
22      example = 120;
23      description = ''
24        Sets the maximum volume.
25      '';
26    };
27  };
28
29  config = mkIf cfg.enable {
30    assertions = [
31      (hm.assertions.assertPlatform "services.swayosd" pkgs platforms.linux)
32    ];
33
34    home.packages = [ cfg.package ];
35
36    systemd.user = {
37      services.swayosd = {
38        Unit = {
39          Description = "Volume/backlight OSD indicator";
40          PartOf = [ "graphical-session.target" ];
41          After = [ "graphical-session.target" ];
42          ConditionEnvironment = "WAYLAND_DISPLAY";
43          Documentation = "man:swayosd(1)";
44        };
45
46        Service = {
47          Type = "simple";
48          ExecStart = "${cfg.package}/bin/swayosd"
49            + (optionalString (cfg.maxVolume != null)
50              " --max-volume ${toString cfg.maxVolume}");
51          Restart = "always";
52        };
53
54        Install = { WantedBy = [ "graphical-session.target" ]; };
55      };
56    };
57  };
58}