fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Anton Bulakhawesome: fix luaModules using pkgs.lua instead of awesome.lua (#3258)8957d531

master
1.5 KiB58 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.xsession.windowManager.awesome;
8  awesome = cfg.package;
9  getLuaPath = lib: dir: "${lib}/${dir}/lua/${awesome.lua.luaversion}";
10  makeSearchPath = lib.concatMapStrings (path:
11    " --search ${getLuaPath path "share"}"
12    + " --search ${getLuaPath path "lib"}");
13
14in {
15  options = {
16    xsession.windowManager.awesome = {
17      enable = mkEnableOption "Awesome window manager";
18
19      package = mkOption {
20        type = types.package;
21        default = pkgs.awesome;
22        defaultText = literalExpression "pkgs.awesome";
23        description = "Package to use for running the Awesome WM.";
24      };
25
26      luaModules = mkOption {
27        default = [ ];
28        type = types.listOf types.package;
29        description = ''
30          List of lua packages available for being
31          used in the Awesome configuration.
32        '';
33        example = literalExpression "[ pkgs.luaPackages.vicious ]";
34      };
35
36      noArgb = mkOption {
37        default = false;
38        type = types.bool;
39        description = ''
40          Disable client transparency support, which can be greatly
41          detrimental to performance in some setups
42        '';
43      };
44    };
45  };
46
47  config = mkIf cfg.enable {
48    assertions = [
49      (hm.assertions.assertPlatform "xsession.windowManager.awesome" pkgs
50        platforms.linux)
51    ];
52
53    home.packages = [ awesome ];
54
55    xsession.windowManager.command = "${awesome}/bin/awesome "
56      + optionalString cfg.noArgb "--no-argb " + makeSearchPath cfg.luaModules;
57  };
58}