fork/home-manager

git clone https://git.julia.blue/fork/home-manager

afreakkxscreensaver: add xscreensaver to service PATH223a73c2

master
1.5 KiB62 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.services.xscreensaver;
8
9in {
10  meta.maintainers = [ maintainers.rycee ];
11
12  options = {
13    services.xscreensaver = {
14      enable = mkEnableOption "XScreenSaver";
15
16      settings = mkOption {
17        type = with types; attrsOf (either bool (either int str));
18        default = { };
19        example = {
20          mode = "blank";
21          lock = false;
22          fadeTicks = 20;
23        };
24        description = ''
25          The settings to use for XScreenSaver.
26        '';
27      };
28    };
29  };
30
31  config = mkIf cfg.enable {
32    assertions = [
33      (lib.hm.assertions.assertPlatform "services.xscreensaver" pkgs
34        lib.platforms.linux)
35    ];
36
37    # To make the xscreensaver-command tool available.
38    home.packages = [ pkgs.xscreensaver ];
39
40    xresources.properties =
41      mapAttrs' (n: nameValuePair "xscreensaver.${n}") cfg.settings;
42
43    systemd.user.services.xscreensaver = {
44      Unit = {
45        Description = "XScreenSaver";
46        After = [ "graphical-session-pre.target" ];
47        PartOf = [ "graphical-session.target" ];
48
49        # Make sure the service is restarted if the settings change.
50        X-Restart-Triggers =
51          [ (builtins.hashString "md5" (builtins.toJSON cfg.settings)) ];
52      };
53
54      Service = {
55        ExecStart = "${pkgs.xscreensaver}/bin/xscreensaver -no-splash";
56        Environment = "PATH=${makeBinPath [ pkgs.xscreensaver ]}";
57      };
58
59      Install = { WantedBy = [ "graphical-session.target" ]; };
60    };
61  };
62}