fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert HelgessonMerge PR #421575790441

master
2.3 KiB93 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.services.xsettingsd;
8
9  renderSettings = settings:
10    concatStrings (mapAttrsToList renderSetting settings);
11
12  renderSetting = key: value: ''
13    ${key} ${renderValue value}
14  '';
15
16  renderValue = value:
17    {
18      int = toString value;
19      bool = if value then "1" else "0";
20      string = ''"${value}"'';
21    }.${builtins.typeOf value};
22
23in {
24  meta.maintainers = [ maintainers.imalison ];
25
26  options = {
27    services.xsettingsd = {
28      enable = mkEnableOption "xsettingsd";
29
30      package = mkOption {
31        type = types.package;
32        default = pkgs.xsettingsd;
33        defaultText = literalExpression "pkgs.xsettingsd";
34        description = ''
35          Package containing the {command}`xsettingsd` program.
36        '';
37      };
38
39      settings = mkOption {
40        type = with types; attrsOf (oneOf [ bool int str ]);
41        default = { };
42        example = literalExpression ''
43          {
44            "Net/ThemeName" = "Numix";
45            "Xft/Antialias" = true;
46            "Xft/Hinting" = true;
47            "Xft/RGBA" = "rgb";
48          }
49        '';
50        description = ''
51          Xsettingsd options for configuration file. See
52          <https://github.com/derat/xsettingsd/wiki/Settings>
53          for documentation on these values.
54        '';
55      };
56
57      configFile = mkOption {
58        type = types.nullOr types.package;
59        internal = true;
60        readOnly = true;
61        default = if cfg.settings == { } then
62          null
63        else
64          pkgs.writeText "xsettingsd.conf" (renderSettings cfg.settings);
65      };
66    };
67  };
68
69  config = mkIf cfg.enable {
70    assertions = [
71      (lib.hm.assertions.assertPlatform "services.xsettingsd" pkgs
72        lib.platforms.linux)
73    ];
74
75    systemd.user.services.xsettingsd = {
76      Unit = {
77        Description = "xsettingsd";
78        After = [ "graphical-session-pre.target" ];
79        PartOf = [ "graphical-session.target" ];
80      };
81
82      Install.WantedBy = [ "graphical-session.target" ];
83
84      Service = {
85        Environment = "PATH=${config.home.profileDirectory}/bin";
86        ExecStart = "${cfg.package}/bin/xsettingsd"
87          + optionalString (cfg.configFile != null)
88          " -c ${escapeShellArg cfg.configFile}";
89        Restart = "on-abort";
90      };
91    };
92  };
93}