fork/home-manager

git clone https://git.julia.blue/fork/home-manager

toonnnix-darwin: simplify activation script invocation95559181

master
917 B31 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  cfg = config.home-manager;
8
9in {
10  imports = [ ../nixos/common.nix ];
11
12  config = mkMerge [
13    { home-manager.extraSpecialArgs.darwinConfig = config; }
14    (mkIf (cfg.users != { }) {
15      system.activationScripts.postActivation.text = concatStringsSep "\n"
16        (mapAttrsToList (username: usercfg: ''
17          echo Activating home-manager configuration for ${username}
18          sudo -u ${username} --set-home ${
19            pkgs.writeShellScript "activation-${username}" ''
20              ${lib.optionalString (cfg.backupFileExtension != null)
21              "export HOME_MANAGER_BACKUP_EXT=${
22                lib.escapeShellArg cfg.backupFileExtension
23              }"}
24              ${lib.optionalString cfg.verbose "export VERBOSE=1"}
25              exec ${usercfg.home.activationPackage}/activate
26            ''
27          }
28        '') cfg.users);
29    })
30  ];
31}