fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Bjørn Forsmannixos: increase TimeoutStartSec from 1m30s to 5mf7848d3e

master
2.7 KiB88 linesraw
1{ config, lib, pkgs, utils, ... }:
2
3with lib;
4
5let
6
7  cfg = config.home-manager;
8
9  serviceEnvironment = optionalAttrs (cfg.backupFileExtension != null) {
10    HOME_MANAGER_BACKUP_EXT = cfg.backupFileExtension;
11  } // optionalAttrs cfg.verbose { VERBOSE = "1"; };
12
13in {
14  imports = [ ./common.nix ];
15
16  config = mkMerge [
17    {
18      home-manager = {
19        extraSpecialArgs.nixosConfig = config;
20
21        sharedModules = [{
22          # The per-user directory inside /etc/profiles is not known by
23          # fontconfig by default.
24          fonts.fontconfig.enable = lib.mkDefault
25            (cfg.useUserPackages && config.fonts.fontconfig.enable);
26
27          # Inherit glibcLocales setting from NixOS.
28          i18n.glibcLocales = lib.mkDefault config.i18n.glibcLocales;
29        }];
30      };
31    }
32    (mkIf (cfg.users != { }) {
33      systemd.services = mapAttrs' (_: usercfg:
34        let username = usercfg.home.username;
35        in nameValuePair ("home-manager-${utils.escapeSystemdPath username}") {
36          description = "Home Manager environment for ${username}";
37          wantedBy = [ "multi-user.target" ];
38          wants = [ "nix-daemon.socket" ];
39          after = [ "nix-daemon.socket" ];
40          before = [ "systemd-user-sessions.service" ];
41
42          environment = serviceEnvironment;
43
44          unitConfig = { RequiresMountsFor = usercfg.home.homeDirectory; };
45
46          stopIfChanged = false;
47
48          serviceConfig = {
49            User = usercfg.home.username;
50            Type = "oneshot";
51            RemainAfterExit = "yes";
52            TimeoutStartSec = "5m";
53            SyslogIdentifier = "hm-activate-${username}";
54
55            ExecStart = let
56              systemctl =
57                "XDG_RUNTIME_DIR=\${XDG_RUNTIME_DIR:-/run/user/$UID} systemctl";
58
59              sed = "${pkgs.gnused}/bin/sed";
60
61              exportedSystemdVariables = concatStringsSep "|" [
62                "DBUS_SESSION_BUS_ADDRESS"
63                "DISPLAY"
64                "WAYLAND_DISPLAY"
65                "XAUTHORITY"
66                "XDG_RUNTIME_DIR"
67              ];
68
69              setupEnv = pkgs.writeScript "hm-setup-env" ''
70                #! ${pkgs.runtimeShell} -el
71
72                # The activation script is run by a login shell to make sure
73                # that the user is given a sane environment.
74                # If the user is logged in, import variables from their current
75                # session environment.
76                eval "$(
77                  ${systemctl} --user show-environment 2> /dev/null \
78                  | ${sed} -En '/^(${exportedSystemdVariables})=/s/^/export /p'
79                )"
80
81                exec "$1/activate"
82              '';
83            in "${setupEnv} ${usercfg.home.activationPackage}";
84          };
85        }) cfg.users;
86    })
87  ];
88}