fork/home-manager

git clone https://git.julia.blue/fork/home-manager

Robert Helgessontests: add mainProgram to stub packagesbaf222f2

master
2.0 KiB81 linesraw
1{ config, lib, pkgs, ... }:
2
3with lib;
4
5let
6
7  stubType = types.submodule ({ name, ... }: {
8    options = {
9      name = mkOption {
10        type = types.str;
11        default = "dummy";
12        description = "The stub package name.";
13      };
14
15      outPath = mkOption {
16        type = types.nullOr types.str;
17        default = "@${name}@";
18        defaultText = literalExpression ''"@''${name}@"'';
19      };
20
21      version = mkOption {
22        type = types.nullOr types.str;
23        default = null;
24        defaultText = literalExpression "pkgs.\${name}.version or null";
25      };
26
27      buildScript = mkOption {
28        type = types.str;
29        default = defaultBuildScript;
30      };
31    };
32  });
33
34  defaultBuildScript = "mkdir $out";
35
36  dummyPackage = pkgs.runCommandLocal "dummy" { meta.mainProgram = "dummy"; }
37    defaultBuildScript;
38
39  mkStubPackage = { name ? "dummy", outPath ? null, version ? null
40    , buildScript ? defaultBuildScript }:
41    let
42      pkg = if name == "dummy" && buildScript == defaultBuildScript then
43        dummyPackage
44      else
45        pkgs.runCommandLocal name {
46          pname = name;
47          meta.mainProgram = name;
48        } buildScript;
49    in pkg // optionalAttrs (outPath != null) {
50      inherit outPath;
51
52      # Prevent getOutput from descending into outputs
53      outputSpecified = true;
54
55      # Allow the original package to be used in derivation inputs
56      __spliced = {
57        buildHost = pkg;
58        hostTarget = pkg;
59      };
60    } // optionalAttrs (version != null) { inherit version; };
61
62in {
63  options.test.stubs = mkOption {
64    type = types.attrsOf stubType;
65    default = { };
66    description =
67      "Package attributes that should be replaced by a stub package.";
68  };
69
70  config = {
71    lib.test.mkStubPackage = mkStubPackage;
72
73    nixpkgs.overlays = mkIf (config.test.stubs != { }) [
74      (self: super:
75        mapAttrs (n: v:
76          mkStubPackage (v // optionalAttrs (v.version == null) {
77            version = super.${n}.version or null;
78          })) config.test.stubs)
79    ];
80  };
81}