fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Infinidogetests/formatting: init2a3efec

develop
3.0 KiB90 linesraw
1{
2  description = "An attempt to better support Minecraft-related content for the Nix ecosystem";
3
4  inputs = {
5    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6    flake-utils.url = "github:numtide/flake-utils";
7    flake-compat = { url = "github:edolstra/flake-compat"; flake = false; };
8  };
9
10  outputs =
11    { self
12    , nixpkgs
13    , flake-utils
14    , ...
15    }@inputs:
16    let
17      mkLib = pkgs: pkgs.lib.extend (_: _: { our = self.lib; });
18
19      mkPackages = pkgs:
20        let
21          # Include build support functions in callPackage,
22          # and include callPackage in itself so it passes to children
23          callPackage = pkgs.newScope ({ lib = mkLib pkgs; inherit callPackage; } // buildSupport);
24          buildSupport = builtins.mapAttrs (n: v: callPackage v) (self.lib.rakeLeaves ./pkgs/build-support);
25        in
26        rec {
27          inherit buildSupport;
28
29          vanillaServers = callPackage ./pkgs/vanilla-servers { };
30          fabricServers = callPackage ./pkgs/fabric-servers { inherit vanillaServers; };
31          quiltServers = callPackage ./pkgs/quilt-servers { inherit vanillaServers; };
32          legacyFabricServers = callPackage ./pkgs/legacy-fabric-servers { inherit vanillaServers; };
33          paperServers = callPackage ./pkgs/paper-servers { inherit vanillaServers; };
34          velocityServers = callPackage ./pkgs/velocity-servers { };
35          minecraftServers = vanillaServers // fabricServers // quiltServers // legacyFabricServers // paperServers;
36
37          vanilla-server = vanillaServers.vanilla;
38          fabric-server = fabricServers.fabric;
39          quilt-server = quiltServers.quilt;
40          paper-server = paperServers.paper;
41          velocity-server = velocityServers.velocity;
42          minecraft-server = vanilla-server;
43        } // (
44          builtins.mapAttrs (n: v: callPackage v { }) (self.lib.rakeLeaves ./pkgs/tools)
45        );
46
47      mkTests = pkgs:
48        let
49          inherit (pkgs.stdenv) isLinux;
50          inherit (pkgs.lib) optionalAttrs mapAttrs;
51          callPackage = pkgs.newScope {
52            inherit self;
53            inherit (self) outputs;
54            lib = mkLib pkgs;
55          };
56        in
57        optionalAttrs isLinux (mapAttrs (n: v: callPackage v { }) (self.lib.rakeLeaves ./tests));
58    in
59    {
60      lib = import ./lib { lib = flake-utils.lib // nixpkgs.lib; };
61
62      overlay = final: prev: mkPackages prev;
63      overlays.default = self.overlay;
64      nixosModules = self.lib.rakeLeaves ./modules;
65    } // flake-utils.lib.eachDefaultSystem (system:
66    let
67      pkgs = import nixpkgs {
68        inherit system;
69        config = { allowUnfree = true; };
70      };
71    in
72    rec {
73      legacyPackages = mkPackages pkgs;
74
75      packages = {
76        inherit (legacyPackages)
77          vanilla-server
78          fabric-server
79          quilt-server
80          paper-server
81          velocity-server
82          minecraft-server
83          nix-modrinth-prefetch;
84      };
85
86      checks = mkTests (pkgs.extend self.outputs.overlays.default) // packages;
87
88      formatter = pkgs.nixpkgs-fmt;
89    });
90}