fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Gabriel Fontespaper: passthru vanilla jar (#44)17e464f

develop
1.4 KiB42 linesraw
1{ callPackage
2, lib
3, jdk8
4, jdk11
5, jdk
6, vanillaServers
7}:
8let
9  inherit (lib.our) escapeVersion;
10  inherit (lib) nameValuePair flatten last versionOlder mapAttrsToList;
11  versions = lib.importJSON ./lock.json;
12
13  # Remove -build... suffix
14  stripBuild = v: builtins.head (builtins.match "(.*)-build.*" v);
15  # Sort by attribute 'attr' using 'f' function
16  sortBy = attr: f: builtins.sort (a: b: f a.${attr} b.${attr});
17
18  # https://docs.papermc.io/paper/getting-started#requirements
19  getRecommendedJavaVersion = v:
20    if versionOlder v "1.11.2" then jdk8
21    else if versionOlder v "1.16.5" then jdk11
22    else jdk;
23
24  packages = mapAttrsToList
25    (mcVersion: builds: sortBy "version" versionOlder (mapAttrsToList
26      (buildNumber: value: callPackage ./derivation.nix {
27        inherit (value) url sha256;
28        version = "${mcVersion}-build.${buildNumber}";
29        jre = getRecommendedJavaVersion mcVersion;
30        minecraft-server = vanillaServers."vanilla-${escapeVersion mcVersion}";
31      })
32      builds))
33    versions;
34
35  # Latest build for each MC version
36  latestBuilds = sortBy "version" versionOlder (map last packages);
37in
38lib.recurseIntoAttrs (builtins.listToAttrs (
39  (map (x: nameValuePair (escapeVersion x.name) x) (flatten packages)) ++
40  (map (x: nameValuePair (escapeVersion (stripBuild x.name)) x) latestBuilds) ++
41  [ (nameValuePair "paper" (last latestBuilds)) ]
42))