fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Infinidogetests: run formatter41e2084

develop
1.5 KiB49 linesraw
1{ nixosTest, outputs }:
2
3nixosTest {
4  name = "files-symlinks";
5  nodes.server = { config, pkgs, lib, ... }: {
6    imports = [ outputs.nixosModules.minecraft-servers ];
7
8    services.minecraft-servers = {
9      enable = true;
10      eula = true;
11      servers.paper = {
12        enable = true;
13        jvmOpts = "-Xmx512M"; # Avoid OOM
14        package = pkgs.paperServers.paper-1_19_4;
15        serverProperties = {
16          server-port = 25565;
17          level-type = "flat"; # Make the test lighter
18          online-mode = false;
19        };
20        symlinks = {
21          # To avoid internet access
22          "cache/mojang_1.19.4.jar" = "${pkgs.vanillaServers.vanilla-1_19_4}/lib/minecraft/server.jar";
23        };
24        files = {
25          # A mutable file
26          "ops.json".value = [{
27            name = "Misterio7x";
28            # Offline mode UUID that is derived from the username
29            # Does not need internet to resolve, and never changes.
30            uuid = "b094c46b-90d6-385a-96d9-5e740ed98070";
31            level = 4;
32          }];
33          "spigot.yml".value = {
34            messages.unknown-command = "Unknown command, dummy!";
35          };
36        };
37      };
38    };
39  };
40
41  testScript = { nodes, ... }: ''
42    name = "paper"
43    grep_logs = lambda expr: f"grep '{expr}' /srv/minecraft/{name}/logs/latest.log"
44
45    server.wait_for_unit(f"minecraft-server-{name}.service")
46    server.wait_for_open_port(25565)
47    server.wait_until_succeeds(grep_logs("Done ([0-9.]\+s)! For help, type \"help\""), timeout=30)
48  '';
49}