fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Infinidogefeat(legacy-fabric-servers): init1c9a6fa

feat/legacy-fabric-servers
1.7 KiB51 linesraw
1{
2  description = "An attempt to better support Minecraft-related content for the Nix ecosystem";
3
4  inputs = {
5    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6    flake-utils.url = "github:numtide/flake-utils";
7  };
8
9  outputs =
10    { self
11    , nixpkgs
12    , flake-utils
13    , ...
14    }@inputs:
15    let
16      packages = pkgs:
17        let
18          callPackage = pkgs.newScope {
19            inherit inputs;
20            lib = pkgs.lib.extend (_: _: { our = self.lib; });
21          };
22        in
23        rec {
24          vanillaServers = callPackage ./pkgs/minecraft-servers { };
25          fabricServers = callPackage ./pkgs/fabric-servers { inherit vanillaServers; };
26          quiltServers = callPackage ./pkgs/quilt-servers { inherit vanillaServers; };
27          legacyFabricServers = callPackage ./pkgs/legacy-fabric-servers { inherit vanillaServers; };
28          minecraftServers = vanillaServers // fabricServers // quiltServers // legacyFabricServers;
29
30          vanilla-server = vanillaServers.vanilla;
31          fabric-server = fabricServers.fabric;
32          quilt-server = quiltServers.quilt;
33          minecraft-server = vanilla-server;
34        } // (
35          builtins.mapAttrs (n: v: callPackage v) (self.lib.rakeLeaves ./pkgs/helpers)
36        ) // (
37          builtins.mapAttrs (n: v: callPackage v { }) (self.lib.rakeLeaves ./pkgs/tools)
38        );
39    in
40    {
41      lib = import ./lib { lib = flake-utils.lib // nixpkgs.lib; };
42
43      overlay = final: prev: packages prev;
44      nixosModules = self.lib.rakeLeaves ./modules;
45    } // flake-utils.lib.eachDefaultSystem (system: {
46      packages = packages (import nixpkgs {
47        inherit system;
48        config = { allowUnfree = true; };
49      });
50    });
51}