fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Nathan Regnerneoforge-servers: initcc15499

lazymc
1.6 KiB56 linesraw
1{
2  lib,
3  callPackage,
4  vanillaServers,
5}:
6let
7  inherit (lib.our) escapeVersion;
8  inherit (lib)
9    nameValuePair
10    flatten
11    last
12    versionOlder
13    mapAttrsToList
14    versions
15    ;
16
17  sortBy = attr: f: builtins.sort (a: b: f a.${attr} b.${attr});
18
19  loaderLocks = lib.importJSON ./loader_locks.json;
20  libraryLocks = lib.importJSON ./library_locks.json;
21  gameLocks = lib.importJSON ./game_locks.json;
22
23  packages = mapAttrsToList (
24    gameVersion: builds:
25    sortBy "version" versionOlder (
26      mapAttrsToList (
27        buildVersion: build:
28        callPackage ./derivation.nix {
29          inherit libraryLocks;
30          build = build // {
31            version = buildVersion;
32          };
33          gameVersion = gameLocks.${gameVersion} // {
34            version = gameVersion;
35          };
36          minecraft-server = vanillaServers."vanilla-${escapeVersion gameVersion}";
37        }
38      ) builds
39    )
40  ) loaderLocks;
41
42  # without padding, versionOlder will incorrectly sort `1.21-21.1.000` before `1.21.8-21.8.000`
43  sortableVersion = drv: "${versions.pad 3 drv.passthru.gameVersion}-${drv.passthru.loaderVersion}";
44
45  # Latest build for each MC version
46  latestBuilds = builtins.sort (a: b: versionOlder (sortableVersion a) (sortableVersion b)) (
47    map last packages
48  );
49in
50lib.recurseIntoAttrs (
51  builtins.listToAttrs (
52    (map (x: nameValuePair (escapeVersion x.name) x) (flatten packages))
53    ++ (map (x: nameValuePair "${x.pname}-${escapeVersion x.passthru.gameVersion}" x) latestBuilds)
54    ++ [ (nameValuePair "neoforge" (last latestBuilds)) ]
55  )
56)